Paulo Custodio > Text-MacroScript > Text::MacroScript

Download:
Text-MacroScript-2.10.tar.gz

Dependencies

Annotate this POD

CPAN RT

New  1
Open  0
View/Report Bugs
Module Version: 2.10   Source   Latest Release: Text-MacroScript-2.10_01

NAME ^

Text::MacroScript - A macro pre-processor with embedded perl capability

SYNOPSIS ^

    use Text::MacroScript;

    # new() for macro processing

    my $Macro = Text::MacroScript->new;
    while( <> ) {
        print $Macro->expand( $_ ) if $_;
    }

    # Canonical use (the filename and line number improves error messages):
    my $Macro = Text::MacroScript->new;
    while( <> ) {
        print $Macro->expand( $_, $ARGV, $. ) if $_;
    }

    # new() for embedded macro processing

    my $Macro = Text::MacroScript->new( -embedded => 1 ); 
    # Delimiters default to <: and :>
    # or
    my $Macro = Text::MacroScript->new( -opendelim => '[[', -closedelim => ']]' );
    while( <> ) {
        print $Macro->expand( $_, $ARGV, $. ) if $_;
    }

    # Create a macro object and create initial macros/scripts from the file(s)
    # given:
    my $Macro = Text::MacroScript->new( 
                    -file => [ 'local.macro', '~/.macro/global.macro' ] 
                    );

    # Create a macro object and create initial macros/scripts from the
    # definition(s) given:
    my $Macro = Text::MacroScript->new(
                    -macro => [
                            [ 'MAX_INT' => '32767' ],
                        ],
                    -script => [
                        [ 'DHM2S' => 
                            [ 
                                my $s = (#0*24*60*60)+(#1*60*60)+(#2*60);
                                "#0 days, #1 hrs, #2 mins = $s secs" 
                            ],
                        ],
                    -variable => [ '*MARKER*' => 0 ],
                    );

    # We may of course use any combination of the options. 

    my $Macro = Text::MacroScript->new( -comment => 1 ); # Create the %%[] macro.

    # define()

    $Macro->define( -macro, $macroname, $macrobody );

    $Macro->define( -script, $scriptname, $scriptbody );

    $Macro->define( -variable, $variablename, $variablebody );

    # undefine()

    $Macro->undefine( -macro, $macroname );

    $Macro->undefine( -script, $scriptname );

    $Macro->undefine( -variable, $variablename );

    # undefine_all()

    $Macro->undefine( -macro );

    $Macro->undefine( -script );

    $Macro->undefine( -variable );

    # list()

    @macros    = $Macro->list( -macro );
    @macros    = $Macro->list( -macro, -namesonly );

    @scripts   = $Macro->list( -script );
    @scripts   = $Macro->list( -script, -namesonly );

    @variables = $Macro->list( -variable );
    @variables = $Macro->list( -variable, -namesonly );

    # load_file() - always treats the contents as within delimiters if we are
    # doing embedded processing.

    $Macro->load_file( $filename );

    # expand_file() - calls expand() for each input line.
    $Macro->expand_file( $filename );
    @expanded = $Macro->expand_file( $filename );
    
    # expand()
    $expanded = $Macro->expand( $unexpanded );
    $expanded = $Macro->expand( $unexpanded, $filename, $line_nr );

This bundle also includes the macropp and macrodir scripts which allows us to expand macros without having to use/understand Text::MacroScript, although you will have to learn the handful of macro commands available and which are documented here and in macropp. macropp provides more documentation on the embedded approach.

The macroutil.pl library supplied provides some functions which you may choose to use in HTML work for example.

MACRO SYSTEMS VS EMBEDDED SYSTEMS ^

Macro systems read all the text, substituting anything which matches a macro name with the macro's body (or script name with the result of the execution of the script). This makes macro systems slower (they have to check for macro/script names everywhere, not just in a delimited section) and more risky (if we choose a macro/script name that normally occurs in the text we'll end up with a mess) than embedded systems. On the other hand because they work on the whole text not just delimited bits, macro systems can perform processing that embedded systems can't. Macro systems are used extensively, for example the CPP, C pre-processor, with its #DEFINE's, etc.

Essentially, embedded systems print all text until they hit an opening delimiter. They then execute any code up until the closing delimiter. The text that results replaces everything between and including the delimeters. They then carry on printing text until they hit an opening delimeter and so on until they've finished processing all the text. This module now provides both approaches.

DESCRIPTION ^

Define macros, scripts and variables in macro files or directly in text files.

Commands can appear in separate macro files which are loaded in either via the text files they process (e.g. via the "%LOAD" command), or can be embedded directly in text files. Almost every command that can appear in a file has an equivalent object method so that programmers can achieve the same things in code as can be achieved by macro commands in texts; there are also additional methods which have no command equivalents.

Most the examples given here use the macro approach. However this module now directly supports an embedded approach and this is now documented. Although you can specify your own delimiters where shown in examples we use the default delimiters of <: and :> throughout.

Public methods

new

  $self = Text::MacroScript->new();
  $self = Text::MacroScript->new( %opts );

Create a new Text::MacroScript object, initialized with the supplied options. By default creates an object for macro processing.

For macro processing:

  my $Macro = Text::MacroScript->new;

For embedded macro processing:

  my $Macro = Text::MacroScript->new( -embedded => 1 ); 
  # Delimiters default to <: and :>

Or specify your own delimiters:

  my $Macro = Text::MacroScript->new( -opendelim => '[[', -closedelim => ']]' );

Or specify one delimiter to use for both (probably not wise):

  my $Macro = Text::MacroScript->new( -opendelim => '%%' ); 
  # -closedelim defaults to -opendelim, e.g. %% in this case

The full list of options that can be specified at object creation:

define_macro

  $Macro->define_macro( $name, $body );

Defines a macro with the given name that expands to the given body when called. If a macro with the same name already exists, it is silently overwritten.

This is the same as the deprecated syntax:

  $Macro->define( -macro, $name, $body );

See also "%DEFINE".

list_macro

  $Macro->list_macro;            # lists to STDOUT
  @output = $Macro->list_macro;  # lists to array
  $Macro->list_macro(-namesonly); # only names

Lists all defined macros to STDOUT or returns the result if called in list context. Accepts an optional parameter -namesonly to list only the macro names and not the body.

undefine_macro

  $Macro->undefine_macro( $name );

If a macro exists with the given name, it is deleted. If not, the function does nothing.

This is the same as the deprecated syntax:

  $Macro->undefine( -macro, $name );

See also "%UNDEFINE".

undefine_all_macro

  $Macro->undefine_all_macro;

Delete all the defined macros.

This is the same as the deprecated syntax:

  $Macro->undefine_all( -macro );

See also "%UNDEFINE_ALL".

define_script

  $Macro->define_script( $name, $body );

Defines a perl script with the given name that executes the given body when called. If a script with the same name already exists, it is silently overwritten.

This is the same as the deprecated syntax:

  $Macro->define( -script, $name, $body );

See also "%DEFINE_SCRIPT".

list_script

  $Macro->list_script;             # lists to STDOUT
  @output = $Macro->list_script;   # lists to array
  $Macro->list_script(-namesonly); # only names

Lists all defined scripts to STDOUT or returns the result if called in list context. Accepts an optional parameter -namesonly to list only the script names and not the body.

undefine_script

  $Macro->undefine_script( $name );

If a script exists with the given name, it is deleted. If not, the function does nothing.

This is the same as the deprecated syntax:

  $Macro->undefine( -script, $name );

See also "%UNDEFINE_SCRIPT".

undefine_all_script

  $Macro->undefine_all_script;

Delete all the defined scripts.

This is the same as the deprecated syntax:

  $Macro->undefine_all( -script );

See also "%UNDEFINE_ALL_SCRIPT".

define_variable

  $Macro->define_variable( $name, $value );

Defines or updates a variable that can be used within macros or perl scripts as #varname.

This is the same as the deprecated syntax:

  $Macro->define( -variable, $name, $value );

See also "%DEFINE_VARIABLE".

list_variable

  $Macro->list_variable;             # lists to STDOUT
  @output = $Macro->list_variable;   # lists to array
  $Macro->list_variable(-namesonly); # only names

Lists all defined variables to STDOUT or returns the result if called in list context. Accepts an optional parameter -namesonly to list only the variable names and not the body.

undefine_variable

  $Macro->undefine_variable( $name );

If a variable exists with the given name, it is deleted. If not, the function does nothing.

This is the same as the deprecated syntax:

  $Macro->undefine( -variable, $name );

See also "%UNDEFINE_VARIABLE".

undefine_all_variable

  $Macro->undefine_all_variable;

Delete all the defined variables.

This is the same as the deprecated syntax:

  $Macro->undefine_all( -variable );

See also "%UNDEFINE_ALL_VARIABLE".

expand

  $text = $Macro->expand( $in );
  $text = $Macro->expand( $in, $filename, $line_nr );

Expands the given $in input and returns the expanded text. The $in is either a text line or an interator that returns a sequence of text lines.

The $filename is optional and defaults to "-". The <$line_nr> is optional and defaults to 1. They are used in error messages to locate the error.

The expansion processes any macro definitions and expands any macro calls found in the input text. expand() buffers internally all the lines required for a multi-line definition, i.e. it can be called once for each line of a multi-line "%DEFINE".

load_file

  $Macro->load_file( $filename );

See also "%LOAD" and macropp -f.

expand_file

  $Macro->expand_file( $filename );
  @expanded = $Macro->expand_file( $filename );

When called in void context, sends output to the current output filehandle. When called in ARRAY context, returns the list of expaned lines.

Calls expand() on each line of the file.

See also "%INCLUDE".

MACRO LANGUAGE ^

This chapter describes the macro language statements processed in the input files.

Defining and using macros

These commands can appear in separate macro files, and/or in the body of files. Wherever a macroname or scriptname is encountered it will be replaced by the body of the macro or the result of the evaluation of the script using any parameters that are given.

Note that if we are using an embedded approach commands, macro names and script names should appear between delimiters. (Except when we "%LOAD" since this assumes the whole file is embedded.

%DEFINE

  %DEFINE macroname [macro body]
  %DEFINE macroname
  multi-line
  macro body
  #0, #1 are the first and second parameters if any used
  %END_DEFINE

Thus, in the body of a file we may have, for example:

  %DEFINE &B [Billericky Rickety Builders]
  Some arbitrary text.
  We are writing to complain to the &B about the shoddy work they did.

If we are taking the embedded approach the example above might become:

  <:%DEFINE BB [Billericky Rickety Builders]:>
  Some arbitrary text.
  We are writing to complain to the <:BB:> about the shoddy work they did.

When using an embedded approach we don't have to make the macro or script name unique within the text, (although each must be distinct from each other), since the delimiters are used to signify them. However since expansion applies recursively it is still wise to make names distinctive.

In files we would write:

  %DEFINE MAC [The Mackintosh Macro]

The equivalent method call is:

    $Macro->define_macro( 'MAC', 'The Mackintosh Macro' );

We can call our macro anything, excluding white-space and special characters used while parsing the input text ([,],(,),#).

All names are case-sensitive.

So a name like %*&! is fine - indeed names which could not normally appear in the text are recommended to avoid having the wrong thing substituted. We should also avoid calling macros, scripts or variables names beginning with #.

Note that if we define a macro and then a script with the same name the script will effectively replace the macro.

We can have parameters (for macros and scripts), e.g.:

  %DEFINE *P [The forename is #0 and the surname is #1]

Parameters used in the source text can contain square brackets since macro will grab up to the last square bracket on the line. The only thing we can't pass are |s since these are used to separate parameters. White-space between the macro name and the [ is optional in definitions but not allowed in the source text.

Parameters are named #0, #1, etc. There is a limit of 100 parameters, i.e. #0..#99, and we must use all those we specify. In the example above we must use *P[param1|param2], e.g. *P[Jim|Hendrix]; if we don't Text::MacroScript will croak. Note that macro names and their parameters must all be on the same line (although this is relaxed if you use paragraph mode).

Because we use # to signify parameters if you require text that consists of a # followed by digits then you should escape the #, e.g.

  %DEFINE *GRAY[<font color="\#121212">#0</font>]

We can use as many more parameters than we need, for example add a third to document: *P[Jim|Hendrix|Musician] will become 'The forename is Jim and the surname is Hendrix', just as in the previous example; the third parameter, 'Musician', will simply be thrown away.

If we take an embedded approach we might write this example thus:

  <:%DEFINE P [The forename is #0 and the surname is #1]:>

and in the text, <:P[Jim|Hendrix]:> will be transformed appropriately.

If we define a macro, script or variable and later define the same name the later definition will replace the earlier one. This is useful for making local macro definitions over-ride global ones, simply by loading the global ones first.

Although macros can have plain textual names like this:

  %DEFINE MAX_INT [32767]

It is generally wise to use a prefix and/or suffix to make sure we don't expand something unintentionally, e.g.

  %DEFINE $MAX_INT [65535]

Macro expansion is no respector of quoted strings or anything else - if the name matches the expansion will take place!

Multi-line definitions are permitted (here's an example I use with the lout typesetting language):

  %DEFINE SCENE
  @Section
    @Title {#0}
  @Begin
  @PP
  @Include {#1}
  @End @Section
  %END_DEFINE

This allows us to write the following in our lout files:

  SCENE[ The title of the scene | scene1.lt ]

which is a lot shorter than the definition.

The body of a macro may not contain a literal null. If you really need one then use a script and represent the null as chr(0).

Converting a macro to a script

This can be achieved very simply. For a one line macro simply enclose the body between qq{ and }, e.g.

  %DEFINE $SURNAME [Baggins]

becomes

  %DEFINE_SCRIPT $SURNAME [qq{Baggins}]

For a multi-line macro use a here document, e.g.

  %DEFINE SCENE
  @Section
    @Title {#0}
  @Begin
  @PP
  @Include {#1}
  @End @Section
  %END_DEFINE

becomes

  %DEFINE_SCRIPT SCENE
  <<__EOT__
  \@Section
    \@Title {#0}
  \@Begin
  \@PP
  \@Include {#1}
  \@End \@Section
  __EOT__
  %END_DEFINE

Note that the @s had to be escaped because they have a special meaning in perl.

%UNDEFINE

Macros can be undefined in files:

  %UNDEFINE *P

and in code:

  $Macro->undefine_macro('*P'); 

Undefining a non-existing macro is not considered an error.

%UNDEFINE_ALL

All macros can be undefined in files:

  %UNDEFINE_ALL

and in code:

  $Macro->undefine_all_macro; 

%DEFINE_SCRIPT

Instead of straight textual substitution, we can have some perl executed (after any parameters have been replaced in the perl text):

  %DEFINE_SCRIPT *ADD ["#0 + #1 = " . (#0 + #1)]

or by using the equivalent method call:

  $Macro->define_script( '*ADD', '"#0 + #1 = " . (#0 + #1)' );

We can call our script anything, excluding white-space characters special characters used while parsing the input text ([,],(,),#).

All names are case-sensitive.

  These would be used as C<*ADD[5|11]> in the text

which would be output as:

  These would be used as 5 + 11 = 16 in the text

In script definitions we can use an alternative way of passing parameters instead of or in addition to the #0 syntax.

This is particularly useful if we want to take a variable number of parameters since the #0 etc syntax does not provide for this. An array called @Param is available to our perl code that has any parameters. This allows things like the following to be achieved:

  %DEFINE_SCRIPT ^PEOPLE
  # We don't use the name hash number params but read straight from the
  # array:
  my $a = "friends and relatives are ";
  $a .= join ", ", @Param;
  $a;
  %END_DEFINE

The above would expand in the following text:

  Her ^PEOPLE[Anna|John|Zebadiah].

to

  Her friends and relatives are Anna, John, Zebadiah.

In addition to having access to the parameters either using the #0 syntax or the @Param array, we can also access any variables that have been defined using "%DEFINE_VARIABLE". These are accessible either using #variablename similarly to the <#0> parameter syntax, or via the %Var hash. Although we can change both @Param and %Var elements in our script, the changes to @Param only apply within the script whereas changes to %Var apply from that point on globally.

Note that if you require a literal # followed by digits in a script body then you must escape the # like this \#.

Here's a simple date-stamp style:

  %DEFINE_SCRIPT *DATESTAMP
  use POSIX;
  "#0 on ".strftime("%Y/%m/%d", localtime(time));
  %END_DEFINE

If we wanted to add the above in code we'd have to make sure the $variables weren't interpolated:

  $Macro->define_script( '*DATESTAMP', <<'__EOT__' );
  use POSIX;
  "#0 on ".strftime("%Y/%m/%d", localtime(time));
  __EOT__

Here's (a somewhat contrived example of) how the above would be used:

  <HTML>
  <HEAD><TITLE>Test Page</TITLE></HEAD>
  <BODY>
  *DATESTAMP[Last Updated]<P>
  This page is up-to-date and will remain valid until *DATESTAMP[midnight]
  </BODY>
  </HTML>

Thus we could have a file, test.html.m containing:

  %DEFINE_SCRIPT *DATESTAMP
  use POSIX;
  "#0 on ".strftime("%Y/%m/%d", localtime(time));
  %END_DEFINE
  <HTML>
  <HEAD><TITLE>Test Page</TITLE></HEAD>
  <BODY>
  *DATESTAMP[Last Updated]<P>
  This page is up-to-date and will remain valid until *DATESTAMP[midnight]
  </BODY>
  </HTML>

which when expanded, either in code using $Macro->expand(), or using the simple macropp utility supplied with Text::MacroScript:

  % macropp test.html.m > test.html

test.html will contain just this:

  <HTML>
  <HEAD><TITLE>Test Page</TITLE></HEAD>
  <BODY>
  Last Updated on 1999/08/21<P>
  This page is up-to-date and will remain valid until midnight on 1999/08/21
  </BODY>
  </HTML>

Of course in practice we wouldn't want to define everything in-line like this. See "%LOAD" later for an alternative.

This example written in embedded style might be written thus:

  <:
  %DEFINE_SCRIPT DATESTAMP
  use POSIX;
  "#0 on ".strftime("%Y/%m/%d", localtime(time));
  %END_DEFINE
  :>
  <HTML>
  <HEAD><TITLE>Test Page</TITLE></HEAD>
  <BODY>
  <!-- Note how the parameter must be within the delimiters. -->
  <:DATESTAMP[Last Updated]:><P>
  This page is up-to-date and will remain valid until <:DATESTAMP[midnight]:>
  </BODY>
  </HTML>

For more (and better) HTML examples see the example file html.macro.

The body of a script may not contain a literal null. If you really need one then represent the null as chr(0).

%UNDEFINE_SCRIPT

Scripts can be undefined in files:

  %UNDEFINE_SCRIPT *DATESTAMP

and in code:

  $Macro->undefine_script('*DATESTAMP'); 

Undefining a non-existing script is not considered an error.

%UNDEFINE_ALL_SCRIPT

All scripts can be undefined in files:

  %UNDEFINE_ALL_SCRIPT

and in code:

  $Macro->undefine_all_script; 

%DEFINE_VARIABLE

We can also define variables:

  %DEFINE_VARIABLE &*! [89.1232]

or in code:

  $Macro->define_variable( '&*!', 89.1232 );

Note that there is no multi-line version of "%DEFINE_VARIABLE".

All current variables are available inside "%DEFINE" macros and "%DEFINE_SCRIPT" as #varname. Inside "%DEFINE_SCRIPT" scripts they are also available in the %Var hash:

  %DEFINE_SCRIPT *TEST1
  $a = '';
  while( my( $key, $val ) each( %Var ) ) {
    $a .= "$key = $val\n";
  }
  $a;
  %END_DEFINE

Here's another example:

  %DEFINE_VARIABLE XCOORD[256]
  %DEFINE_VARIABLE YCOORD[112]
  The X coord is *SCALE[X|16] and the Y coord is *SCALE[Y|16] 
    
  %DEFINE_SCRIPT *SCALE
  my $coord = shift @Param;
  my $scale = shift @Param;
  my $val   = $Var{$coord};
  $val %= scale; # Scale it
  $val; 
  %END_DEFINE

Variables can be modified within script "%DEFINE"s, e.g.

    %DEFINE_VARIABLE VV[Foxtrot]
    # VV eq 'Foxtrot'
    # other text
    # Here we use the #variable synax:
    %DEFINE_SCRIPT VV[#VV='Alpha']
    # VV eq 'Alpha' - note that we *must* refer to the script (as we've done
    # on the line following) for it to execute.
    # other text
    # Here we use perl syntax:
    %DEFINE_SCRIPT VV[$Var{'VV'}='Tango']
    # VV eq 'Tango' - note that we *must* refer to the script (as we've done
    # on the line following) for it to execute.

As we can see variables support the #variable syntax similarly to parameters which support #0 etc and ara available in scripts via the @Param array. Note that changing parameters within a script only apply within the script; whereas changing variables in the %Var hash in a script changes them from that point on globally.

Variables are also used with "%CASE".

%UNDEFINE_VARIABLE

Variables can be undefined in files:

  %UNDEFINE_VARIABLE &*!

and in code:

  $Macro->undefine_variable('&*!'); 

Undefining a non-existing variable is not considered an error.

%UNDEFINE_ALL_VARIABLE

All variables can be undefined in files:

  %UNDEFINE_ALL_VARIABLE

and in code:

  $Macro->undefine_all_variable; 

One use of undefining everything is to ensure we get a clean start. We might head up our files thus:

  %UNDEFINE_ALL
  %UNDEFINE_ALL_SCRIPT
  %UNDEFINE_ALL_VARIABLE
  %LOAD[mymacros]
  text goes here

Loading and including files

Although we can define macros directly in the files that require them it is often more useful to define them separately and include them in all those that need them.

One way of achieving this is to load in the macros/scripts first and then process the file(s). In code this would be achieved like this:

  $Macro->load_file( $macro_file );             # loads definitions only
  $Macro->expand_file( $file );                 # expands definitions to STDOUT
  my @expanded = $Macro->expand_file( $file );  # expands to array.

From the command line it would be achieved thus:

  % macropp -f html.macros test.html.m > test.html

One disadvantage of this approach, especially if we have lots of macro files, is that we can easily forget which macro files are required by which text files. One solution to this is to go back to %DEFINEing in the text files themselves, but this would lose reusability. The answer to both these problems is to use the %LOAD command which loads the definitions from the named file at the point it appears in the text file:

  %LOAD[~/.macro/html.macros]
  <HTML>
  <HEAD><TITLE>Test Page Again</TITLE></HEAD>
  <BODY>
  *DATESTAMP[Last Updated]<P>
  This page will remain valid until *DATESTAMP[midnight]
  </BODY>
  </HTML>

The above text has the same output but we don't have to remember or explicitly load the macros. In code we can simply do this:

  my @expanded = $Macro->expand_file( $file );

or from the command line:

  % macropp test.html.m > test.html

At the beginning of our lout typesetting files we might put this line:

    %LOAD[local.macros]

The first line of the local.macros file is:

    %LOAD[~/.macro/lout.macros]

So this loads both global macros then local ones (which if they have the same name will of course over-ride).

This saves repeating the %DEFINE definitions in all the files and makes maintenance easier.

%LOAD loads perl scripts and macros, but ignores any other text. Thus we can use %LOAD, or its method equivalent load_file(), on any file, and it will only ever instantiate macros and scripts and produce no output. When we are using embedded processing any file %LOADed is treated as if wrapped in delimiters.

If we want to include the entire contents of another file, and perform macro expansion on that file then use %INCLUDE, e.g.

    %INCLUDE[/path/to/file/with/scripts-and-macros-and-text]

The %INCLUDE command will instantiate any macros and scripts it encounters and include all other lines of text (with macro/script expansion) in the output stream.

Macros and scripts are expanded in the following order: 1. scripts (longest named first, shortest named last) 2. macros (longest named first, shortest named last)

%LOAD

  %LOAD[file]

or its code equivalent

  $Macro->load_file( $filename );

instatiates any definitions that appear in the file, but ignores any other text and produces no output. When we are using embedded processing any file "%LOAD"ed is treated as if wrapped in delimiters.

This is equivalent to calling macropp -f.

New defintions of the same macro override old defintions, thus one can first "%LOAD" a global macro file, and then a local project file that can override some of the global macros.

%INCLUDE

  %INCLUDE[file]

or its code equivalent

  $Macro->expand_file( $filename );

instatiates any definitions that appear in the file, expands definitions and sends any other text to the current output filehandle.

%REQUIRE

We often want our scripts to have access to a bundle of functions that we have created or that are in other modules. This can now be achieved by:

  %REQUIRE[/path/to/mylibrary.pl]

An example library macroutil.pl is provided with examples of usage in html.macro.

There is no equivalent object method because if we're writing code we can use or c<require> as needed and if we're writing macros then we use "%REQUIRE".

Control Structures

%CASE

It is possible to selectively skip parts of the text.

    %CASE[0]
    All the text here will be discarded.
    No matter how much there is.
    This is effectively a `comment' case.
    %END_CASE

The above is useful for multi-line comments.

We can also skip selectively. Here's an if...then:

    %CASE[#OS eq 'Linux']
    Skipped if the condition is FALSE. 
    %END_CASE

The condition can be any perl fragment. We can use previously defined variables either using the #variable syntax as shown above or using the exported perl name, thus in this case either #OS, or %Var{'OS'} whichever we prefer.

If the condition is true the text is output with macro/script expansion as normal; if the condition is false the text is skipped.

The if...then...else structure:

    %DEFINE_VARIABLE OS[Linux]

    %CASE[$Var{'OS'} eq 'Linux']
    Linux specific stuff.
    %CASE[#OS ne 'Linux']
    Non-linux stuff - note that both references to the OS variable are
    identical in the expression (#OS is converted internally to $Var{'0S'} so
    the eval sees the same code in both cases
    %END_CASE

Although nested "%CASE"s are not supported we can get the same functionality (and indeed more versatility because we can use full perl expressions), e.g.:

    %DEFINE_VARIABLE TARGET[Linux]

    %CASE[#TARGET eq 'Win32' or #TARGET eq 'DOS']
    Win32/DOS stuff.
    %CASE[#TARGET eq 'Win32']
    Win32 only stuff.
    %CASE[#TARGET eq 'DOS']
    DOS only stuff.
    %CASE[#TARGET eq 'Win32' or #TARGET eq 'DOS']
    More Win32/DOS stuff.
    %END_CASE

Although macropp doesn't support nested "%CASE"'s we can still represent logic like this:

    if cond1 then
        if cond2
            do cond1 + cond2 stuff
        else
            do cond1 stuff
        end if
    else
        do other stuff
    end if

By `unrolling' the expression and writing something like this:

    %CASE[#cond1 and #cond2]
        do cond1 + cond2 stuff
    %CASE[#cond1 and (not #cond2)]
        do cond1 stuff
    %CASE[(not #cond1) and (not #cond2)]
        do other stuff
    %END_CASE

In other words we must fully specify the conditions for each case.

We can use any other macro/script command within "%CASE" commands, e.g. "%DEFINE"s, etc., as well as have any text that will be macro/script expanded as normal.

Comments

Generally the text files that we process are in formats that support commenting, e.g. HTML:

    <!-- This is an HTML comment -->

Sometimes however we want to put comments in our macro source files that won't end up in the output files. One simple way of achieving this is to define a macro whose body is empty; when its called with any number of parameters (our comments), their text is thrown away:

  %DEFINE %%[]

which is used like this in texts:

  The comment comes %%[Here | [anything] put here will disappear]here!

The output of the above will be:

    The comment comes here!

We can add the definition in code:

    $Macro->define( -macro, '%%', '' );

Or the macro can be added automatically for us when we create the Macro object:

    my $Macro = Text::MacroScript->new( -comment => 1 ); 
    # All other options may be used too of course.

However the easiest way to comment is to use "%CASE":

    %CASE[0]
    This unconditionally skips text up until the end marker since the
    condition is always false.
    %END_CASE

IMPORTABLE FUNCTIONS ^

In version 1.25 I introduced some useful importable functions. These have now been removed from the module. Instead I supply a perl library macroutil.pl which has these functions (abspath, relpath, today) since Text::MacroScript can now `require' in any library file you like using the "%REQUIRE" directive.

EXAMPLES ^

I now include a sample html.macro file for use with HTML documents. It uses the macrodir program (supplied). The macro examples include macros which use relpath and also two macros which will include `new' and `updated' images up until a specified expiry date using variables.

(Also see DESCRIPTION.)

BUGS ^

Lousy error reporting for embedded perl in most cases.

AUTHOR ^

Mark Summerfield. I can be contacted as <summer@perlpress.com> - please include the word 'macro' in the subject line.

MAINTAINER ^

Since 2015, Paulo Custodio.

This module repository is kept in Github, please feel free to submit issues, fork and send pull requests.

    https://github.com/pauloscustodio/Text-MacroScript

COPYRIGHT ^

Copyright (c) Mark Summerfield 1999-2000. All Rights Reserved.

Copyright (c) Paulo Custodio 2015. All Rights Reserved.

This module may be used/distributed/modified under the LGPL.

syntax highlighting: