Home · Authors · Recent · News · Mirrors · FAQ · Feedback

in  
Vincent Pit > Variable-Magic > Variable::Magic

Download:
Variable-Magic-0.38.tar.gz

Dependencies

Annotate this POD

Website

View/Report Bugs

Module Version: 0.38   Source  

NAME ^

Variable::Magic - Associate user-defined magic to variables from Perl.

VERSION ^

Version 0.38

SYNOPSIS ^

    use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;

    { # A variable tracer
     my $wiz = wizard set  => sub { print "now set to ${$_[0]}!\n" },
                      free => sub { print "destroyed!\n" };

     my $a = 1;
     cast $a, $wiz;
     $a = 2;        # "now set to 2!"
    }               # "destroyed!"

    { # A hash with a default value
     my $wiz = wizard data     => sub { $_[1] },
                      fetch    => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
                      store    => sub { print "key $_[2] stored in $_[-1]\n" },
                      copy_key => 1,
                      op_info  => VMG_OP_INFO_NAME;

     my %h = (_default => 0, apple => 2);
     cast %h, $wiz, '_default';
     print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
     $h{pear} = 1;           # "key pear stored in helem"
    }

DESCRIPTION ^

Magic is Perl way of enhancing objects. This mechanism lets the user add extra data to any variable and hook syntaxical operations (such as access, assignment or destruction) that can be applied to it. With this module, you can add your own magic to any variable without having to write a single line of XS.

You'll realize that these magic variables look a lot like tied variables. It's not surprising, as tied variables are implemented as a special kind of magic, just like any 'irregular' Perl variable : scalars like $!, $( or $^W, the %ENV and %SIG hashes, the @ISA array, vec() and substr() lvalues, threads::shared variables... They all share the same underlying C API, and this module gives you direct access to it.

Still, the magic made available by this module differs from tieing and overloading in several ways :

The operations that can be overloaded are :

The following actions only apply to hashes and are available iff VMG_UVAR is true. They are referred to as uvar magics.

You can refer to the tests to have more insight of where the different magics are invoked.

To prevent any clash between different magics defined with this module, an unique numerical signature is attached to each kind of magic (i.e. each set of callbacks for magic operations). At the C level, magic tokens owned by magic created by this module have their mg->mg_private field set to 0x3891 or 0x3892, so please don't use these magic (sic) numbers in other extensions.

FUNCTIONS ^

wizard

    wizard data     => sub { ... },
           get      => sub { my ($ref, $data [, $op]) = @_; ... },
           set      => sub { my ($ref, $data [, $op]) = @_; ... },
           len      => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
           clear    => sub { my ($ref, $data [, $op]) = @_; ... },
           free     => sub { my ($ref, $data [, $op]) = @_, ... },
           copy     => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
           local    => sub { my ($ref, $data [, $op]) = @_; ... },
           fetch    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
           store    => sub { my ($ref, $data, $key [, $op]) = @_; ... },
           exists   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
           delete   => sub { my ($ref, $data, $key [, $op]) = @_; ... },
           copy_key => $bool,
           op_info  => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]

This function creates a 'wizard', an opaque type that holds the magic information. It takes a list of keys / values as argument, whose keys can be :

    # A simple scalar tracer
    my $wiz = wizard get  => sub { print STDERR "got ${$_[0]}\n" },
                     set  => sub { print STDERR "set to ${$_[0]}\n" },
                     free => sub { print STDERR "${$_[0]} was deleted\n" }

Note that free callbacks are never called during global destruction, as there's no way to ensure that the wizard and the free callback weren't destroyed before the variable.

gensig

With this tool, you can manually generate random magic signature between SIG_MIN and SIG_MAX inclusive. That's the way "wizard" creates them when no signature is supplied.

    # Generate a signature
    my $sig = gensig;

This function is deprecated and will be removed in december 2009.

getsig

    getsig $wiz

This accessor returns the magic signature of this wizard.

    # Get $wiz signature
    my $sig = getsig $wiz;

This function is deprecated and will be removed in december 2009.

cast

    cast [$@%&*]var, $wiz, ...

This function associates $wiz magic to the variable supplied, without overwriting any other kind of magic. It returns true on success or when $wiz magic is already present, and croaks on error. All extra arguments specified after $wiz are passed to the private data constructor in @_[1 .. @_-1]. If the variable isn't a hash, any uvar callback of the wizard is safely ignored.

    # Casts $wiz onto $x, and pass '1' to the data constructor.
    my $x;
    cast $x, $wiz, 1;

The var argument can be an array or hash value. Magic for those behaves like for any other scalar, except that it is dispelled when the entry is deleted from the container. For example, if you want to call POSIX::tzset each time the 'TZ' environment variable is changed in %ENV, you can use :

    use POSIX;
    cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };

If you want to overcome the possible deletion of the 'TZ' entry, you have no choice but to rely on store uvar magic.

getdata

    getdata [$@%&*]var, $wiz

This accessor fetches the private data associated with the magic $wiz in the variable. It croaks when $wiz do not represent a valid magic object, and returns an empty list if no such magic is attached to the variable or when the wizard has no data constructor.

    # Get the attached data, or undef if the wizard does not attach any.
    my $data = getdata $x, $wiz;

dispell

    dispell [$@%&*]variable, $wiz

The exact opposite of "cast" : it dissociates $wiz magic from the variable. This function returns true on success, 0 when no magic represented by $wiz could be found in the variable, and croaks if the supplied wizard is invalid.

    # Dispell now.
    die 'no such magic in $x' unless dispell $x, $wiz;

CONSTANTS ^

SIG_MIN

The minimum integer used as a signature for user-defined magic.

This constant is deprecated and will be removed in december 2009.

SIG_MAX

The maximum integer used as a signature for user-defined magic.

This constant is deprecated and will be removed in december 2009.

SIG_NBR

    SIG_NBR = SIG_MAX - SIG_MIN + 1

This constant is deprecated and will be removed in december 2009.

MGf_COPY

Evaluates to true iff the 'copy' magic is available.

MGf_DUP

Evaluates to true iff the 'dup' magic is available.

MGf_LOCAL

Evaluates to true iff the 'local' magic is available.

VMG_UVAR

When this constant is true, you can use the fetch,store,exists,delete callbacks on hashes.

VMG_COMPAT_ARRAY_PUSH_NOLEN

True for perls that don't call 'len' magic when you push an element in a magical array. Starting from perl 5.11.0, this only refers to pushes in non-void context and hence is false.

VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID

True for perls that don't call 'len' magic when you push in void context an element in a magical array.

VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID

True for perls that don't call 'len' magic when you unshift in void context an element in a magical array.

VMG_COMPAT_ARRAY_UNDEF_CLEAR

True for perls that call 'clear' magic when undefining magical arrays.

VMG_COMPAT_SCALAR_LENGTH_NOLEN

True for perls that don't call 'len' magic when taking the length of a magical scalar.

VMG_PERL_PATCHLEVEL

The perl patchlevel this module was built with, or 0 for non-debugging perls.

VMG_THREADSAFE

True iff this module could have been built with thread-safety features enabled.

VMG_FORKSAFE

True iff this module could have been built with fork-safety features enabled. This will always be true except on Windows where it's false for perl 5.10.0 and below .

VMG_OP_INFO_NAME

Value to pass with op_info to get the current op name in the magic callbacks.

VMG_OP_INFO_OBJECT

Value to pass with op_info to get a B::OP object representing the current op in the magic callbacks.

COOKBOOK ^

Associate an object to any perl variable

This can be useful for passing user data through limited APIs.

    {
     package Magical::UserData;

     use Variable::Magic qw/wizard cast getdata/;

     my $wiz = wizard data => sub { \$_[1] };

     sub ud (\[$@%*&]) : lvalue {
      my ($var) = @_;
      my $data = &getdata($var, $wiz);
      unless (defined $data) {
       &cast($var, $wiz);
       $data = &getdata($var, $wiz);
       die "Couldn't cast UserData magic onto the variable" unless defined $data;
      }
      $$data;
     }
    }

    {
     BEGIN { *ud = \&Magical::UserData::ud }

     my $cb;
     $cb = sub { print 'Hello, ', ud(&$cb), "!\n" };

     ud(&$cb) = 'world';
     $cb->(); # Hello, world!
    }

Recursively cast magic on datastructures

cast can be called from any magical callback, and in particular from data. This allows you to recursively cast magic on datastructures :

    my $wiz;
    $wiz = wizard data => sub {
     my ($var, $depth) = @_;
     $depth ||= 0;
     my $r = ref $var;
     if ($r eq 'ARRAY') {
      &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
     } elsif ($r eq 'HASH') {
      &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
     }
     return $depth;
    },
    free => sub {
     my ($var, $depth) = @_;
     my $r = ref $var;
     print "free $r at depth $depth\n";
     ();
    };

    {
     my %h = (
      a => [ 1, 2 ],
      b => { c => 3 }
     );
     cast %h, $wiz;
    }

When %h goes out of scope, this will print something among the lines of :

    free HASH at depth 0
    free HASH at depth 1
    free SCALAR at depth 2
    free ARRAY at depth 1
    free SCALAR at depth 3
    free SCALAR at depth 3

Of course, this example does nothing with the values that are added after the cast.

PERL MAGIC HISTORY ^

The places where magic is invoked have changed a bit through perl history. Here's a little list of the most recent ones.

EXPORT ^

The functions "wizard", "gensig", "getsig", "cast", "getdata" and "dispell" are only exported on request. All of them are exported by the tags ':funcs' and ':all'.

All the constants are also only exported on request, either individually or by the tags ':consts' and ':all'.

CAVEATS ^

If you store a magic object in the private data slot, the magic won't be accessible by "getdata" since it's not copied by assignment. The only way to address this would be to return a reference.

If you define a wizard with a free callback and cast it on itself, this destructor won't be called because the wizard will be destroyed first.

DEPENDENCIES ^

perl 5.8.

Carp (standard since perl 5), XSLoader (standard since perl 5.006).

Copy tests need Tie::Array (standard since perl 5.005) and Tie::Hash (since 5.002).

Some uvar tests need Hash::Util::FieldHash (standard since perl 5.009004).

Glob tests need Symbol (standard since perl 5.002).

Threads tests need threads and threads::shared.

SEE ALSO ^

perlguts and perlapi for internal information about magic.

perltie and overload for other ways of enhancing objects.

AUTHOR ^

Vincent Pit, <perl at profvince.com>, http://www.profvince.com.

You can contact me by mail or on irc.perl.org (vincent).

BUGS ^

Please report any bugs or feature requests to bug-variable-magic at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT ^

You can find documentation for this module with the perldoc command.

    perldoc Variable::Magic

Tests code coverage report is available at http://www.profvince.com/perl/cover/Variable-Magic.

COPYRIGHT & LICENSE ^

Copyright 2007-2009 Vincent Pit, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

59250 Uploads, 19049 Distributions 74834 Modules, 7807 Uploaders
hosted by YellowBot
do. tag. write. share.