#!/usr/bin/perl -w
# A tool to build a perl release tarball
# Very basic but functional - if you're on a unix system.
#
# If you're on Win32 then it should still work, but various Unix command-line
# tools will need to be available somewhere. An obvious choice is to install
# Cygwin and ensure its 'bin' folder is on the PATH in the shell where you run
# this script. The Cygwin 'bin' folder needs to precede the Windows 'system32'
# folder so that Cygwin's 'find' command is found in preference to the Windows
# 'find' command. Your Cygwin installation will need to contain at least the
# 'cpio' command, in addition to the commands installed by default, and it will
# also be useful to have 'curl' and 'diffstat' installed too for later stages
# of the release process (namely, Porting\corelist.pl and generating the commit
# statistics for the perlXYZdelta.pod file respectively). Finally, ensure that
# the 'awk' and 'shasum' commands are copies of gawk.exe and sha1sum.exe
# respectively, rather than the links to them that only work in a Cygwin bash
# shell which they are by default.
#
# No matter how automated this gets, you'll always need to read
# and re-read pumpkin.pod and release_managers_guide.pod to
# check for things to be done at various stages of the process.
#
# Tim Bunce, June 1997
use ExtUtils::Manifest qw(fullcheck);
$ExtUtils::Manifest::Quiet = 1;
use Getopt::Std;
$|=1;
sub usage { die <<EOF; }
usage: $0 [ -r rootdir ] [-s suffix ] [ -b ] [ -n ]
-r rootdir directory under which to create the build dir and tarball
defaults to '..'
-s suffix suffix to append to to the perl-x.y.z dir and tarball name
defaults to the concatenation of the local_patches entry
in patchlevel.h (or blank, if none)
-b make a .bz2 file in addtion to a .gz file
-n do not make any tarballs, just the directory
EOF
my %opts;
getopts('bnr:s:', \%opts) or usage;
@ARGV && usage;
$relroot = defined $opts{r} ? $opts{r} : "..";
die "Must be in root of the perl source tree.\n"
unless -f "./MANIFEST" and -f "patchlevel.h";
open PATCHLEVEL,"<patchlevel.h" or die;
my @patchlevel_h = <PATCHLEVEL>;
close PATCHLEVEL;
my $patchlevel_h = join "", grep { /^#\s*define/ } @patchlevel_h;
print $patchlevel_h;
$revision = $1 if $patchlevel_h =~ /PERL_REVISION\s+(\d+)/;
$patchlevel = $1 if $patchlevel_h =~ /PERL_VERSION\s+(\d+)/;
$subversion = $1 if $patchlevel_h =~ /PERL_SUBVERSION\s+(\d+)/;
die "Unable to parse patchlevel.h" unless $subversion >= 0;
$vers = sprintf("%d.%d.%d", $revision, $patchlevel, $subversion);
# fetch list of local patches
my (@local_patches, @lpatch_tags, $lpatch_tags);
@local_patches = grep { !/^\s*,?NULL/ && ! /,"uncommitted-changes"/ }
grep { /^static.*local_patches/../^};/ }
@patchlevel_h;
@lpatch_tags = map { /^\s*,"(\w+)/ } @local_patches;
$lpatch_tags = join "-", @lpatch_tags;
$perl = "perl-$vers";
$reldir = "$perl";
$lpatch_tags = $opts{s} if defined $opts{s};
$reldir .= "-$lpatch_tags" if $lpatch_tags;
print "\nMaking a release for $perl in $relroot/$reldir\n\n";
print "Cross-checking the MANIFEST...\n";
($missfile, $missentry) = fullcheck();
@$missentry
= grep {$_ !~ m!^\.git/! and $_ !~ m!(?:/|^)\.gitignore!} @$missentry;
if (@$missfile ) {
warn "Can't make a release with MANIFEST files missing:\n";
warn "\t".$_."\n" for (@$missfile);
}
if (@$missentry ) {
warn "Can't make a release with files not listed in MANIFEST\n";
warn "\t".$_."\n" for (@$missentry);
}
if ("@$missentry" =~ m/\.orig\b/) {
# Handy listing of find command and .orig files from patching work.
# I tend to run 'xargs rm' and copy and paste the file list.
my $cmd = "find . -name '*.orig' -print";
print "$cmd\n";
system($cmd);
}
die "Aborted.\n" if @$missentry or @$missfile;
print "\n";
# VMS no longer has hardcoded version numbers descrip.mms
print "Creating $relroot/$reldir release directory...\n";
die "$relroot/$reldir release directory already exists\n" if -e "$relroot/$reldir";
die "$relroot/$reldir.tar.gz release file already exists\n" if -e "$relroot/$reldir.tar.gz";
mkdir("$relroot/$reldir", 0755) or die "mkdir $relroot/$reldir: $!\n";
print "\n";
print "Copying files to release directory...\n";
# ExtUtils::Manifest maniread does not preserve the order
$cmd = "awk '{print \$1}' MANIFEST | cpio -pdm $relroot/$reldir";
system($cmd) == 0
or die "$cmd failed";
print "\n";
chdir "$relroot/$reldir" or die $!;
print "Setting file permissions...\n";
system("find . -type f -print | xargs chmod 0444");
system("find . -type d -print | xargs chmod 0755");
my @exe = map { my ($f) = split; glob($f) }
grep { $_ !~ /\A#/ && $_ !~ /\A\s*\z/ }
map { split "\n" }
do { local (@ARGV, $/) = 'Porting/exec-bit.txt'; <> };
system("chmod +x @exe") == 0
or die "system: $!";
my @writables = qw(
NetWare/config_H.wc
NetWare/Makefile
feature.h
lib/feature.pm
keywords.h
keywords.c
opcode.h
opnames.h
pp_proto.h
proto.h
embed.h
embedvar.h
overload.c
overload.h
mg_vtable.h
perlapi.h
perlapi.c
cpan/Devel-PPPort/module2.c
cpan/Devel-PPPort/module3.c
reentr.c
reentr.h
regcharclass.h
regnodes.h
warnings.h
lib/warnings.pm
win32/Makefile
win32/Makefile.ce
win32/makefile.mk
win32/config_H.ce
win32/config_H.gc
win32/config_H.gc64
win32/config_H.vc
win32/config_H.vc64
utils/Makefile
uconfig.h
);
system("chmod u+w @writables") == 0
or die "system: $!";
chdir ".." or die $!;
exit if $opts{n};
my $src = (-e $perl) ? $perl : 'perl'; # 'perl' in maint branch
print "Checking if you have 7z...\n";
my $output_7z = `7z 2>&1`;
my $have_7z = defined $output_7z && $output_7z =~ /7-Zip/;
print "Checking if you have advdef...\n";
my $output_advdef = `advdef --version 2>&1`;
my $have_advdef = defined $output_advdef && $output_advdef =~ /advancecomp/;
if ($have_7z) {
print "Creating and compressing the tar.gz file with 7z...\n";
$cmd = "tar cf - $reldir | 7z a -tgzip -mx9 -bd -si $reldir.tar.gz";
system($cmd) == 0 or die "$cmd failed";
} else {
print "Creating and compressing the tar.gz file...\n";
$cmd = "tar cf - $reldir | gzip --best > $reldir.tar.gz";
system($cmd) == 0 or die "$cmd failed";
if ($have_advdef) {
print "Recompressing the tar.gz file with advdef...\n";
$cmd = "advdef -z -4 $reldir.tar.gz";
system($cmd) == 0 or die "$cmd failed";
}
}
if ($opts{b}) {
if ($have_7z) {
print "Creating and compressing the tar.bz2 file with 7z...\n";
$cmd = "tar cf - $reldir | 7z a -tbzip2 -mx9 -bd -si $reldir.tar.bz2";
system($cmd) == 0 or die "$cmd failed";
} else {
print "Creating and compressing the tar.bz2 file...\n";
$cmd = "tar cf - $reldir | bzip2 > $reldir.tar.bz2";
system($cmd) == 0 or die "$cmd failed";
}
}
print "\n";
system("ls -ld $perl*");
print "\n";
my $null = $^O eq 'MSWin32' ? 'NUL' : '/dev/null';
for my $sha (qw(sha1 shasum sha1sum)) {
if (`which $sha 2>$null`) {
system("$sha $perl*.tar.*");
last;
}
}