The Perl Toolchain Summit needs more sponsors. If your company depends on Perl, please support this very important event.
 / 
MooX-Options-4.005
River stage three • 48 direct dependents • 149 total dependents
24 ++
/ MooX::Options

NAME

MooX::Options - Explicit Options eXtension for Object Class

VERSION

version 4.005

SYNOPSIS

In myOptions.pm :

  package myOptions;
  use Moo;
  use MooX::Options;
  
  option 'show_this_file' => (
      is => 'ro',
      format => 's',
      required => 1,
      doc => 'the file to display'
  );
  1;

In myTool.pl :

  use feature 'say';
  use myOptions;
  use Path::Class;
  
  my $opt = myOptions->new_with_options;
  
  say "Content of the file : ",
       file($opt->show_this_file)->slurp;

To use it :

  perl myTool.pl --show_this_file=myFile.txt
  Content of the file: myFile content

The help message :

  perl myTool.pl --help
  USAGE: myTool.pl [-h] [long options...]
  
      --show_this_file: String
          the file to display
      
      -h --help:
          show this help message
      
      --man:
          show the manual

The usage message :

  perl myTool.pl --usage
  USAGE: myTool.pl [ --show_this_file=String ] [ --usage ] [ --help ] [ --man ]

The manual :

  perl myTool.pl --man

DESCRIPTION

Create a command line tool with your Mo, Moo, Moose objects.

Everything is explicit. You have an 'option' keyword to replace the usual 'has' to explicitly use your attribute into the command line.

The 'option' keyword takes additional parameters and use Getopt::Long::Descriptive to generate a command line tool.

IMPORTED METHODS

The list of the methods automatically imported into your class.

new_with_options

It will parse your command line params and your inline params, validate and call the 'new' method.

  myTool --str=ko

  t->new_with_options()->str # ko
  t->new_with_options(str => 'ok')->str #ok

option

The option keyword replace the 'has' method, and add support specials options for the command line only.

See "OPTION PARAMETERS" for the documentation.

options_usage | --help

It display the usage message and return the exit code

  my $t = t->new_with_options();
  my $exit_code = 1;
  my $pre_message = "str is not valid";
  $t->options_usage($exit_code, $pre_message);

This method is also automatically fire if the command option "--help" is passed.

  myTool --help

options_man | --man

It display the manual.

  my $t = t->new_with_options();
  $t->options_man();

This is automatically fire if the command option "--man" is passed.

  myTool --man

options_short_usage | --usage

It display a short version of the help message.

  my $t = t->new_with_options();
  $t->options_short_usage($exit_code);

This is automatically fire if the command option "--usage" is passed.

  myTool --usage

IMPORT PARAMETERS

The list of parameters support by MooX::Options.

flavour

Pass extra arguments for Getopt::Long::Descriptive. It is usefull if you want to configure Getopt::Long.

  use MooX::Options flavour => [qw( pass_through )];

Any flavour is pass to Getopt::Long as a configuration, check the doc to see what is possible.

protect_argv

By default, @ARGV is protected. if you want to do something else on it, use this option and it will change the real @ARGV.

  use MooX::Options protect_argv => 0;

skip_options

If you have Role with options and your want to disactivate some of them, you can use this parameter. In that case, the 'option' keyword will just works like an 'has'.

  use MooX::Options skip_options => [qw/multi/];

prefer_commandline

By default, arguments to new_with_options have a higher priority than the commandline options.

This parameter give to the commandline an higher priority.

  use MooX::Options prefer_commandline => 1;

with_config_from_file

This parameter will load MooX::ConfigFromFile in your module. The config option will be used between the commandline and the parameters.

myTool :

  use MooX::Options with_config_from_file => 1;

In /etc/myTool.json

  {"test" : 1}

OPTION PARAMETERS

The keyword option extend the keyword has with specific parameters for the commandline.

doc | documentation

Documentation for the command line option.

long_doc

Documentation for the man page. By default the doc parameter will be used.

See also Man parameters to get more examples to build a nice man page.

required

This attribute indicate that the parameter is mandatory. This attribute is not really used by MooX::Options but the error message will be handle by it to display a consistant error message.

format

Format of the params. It is the same as Getopt::Long::Descriptive.

  • i : integer

  • i@: array of integer

  • s : string

  • s@: array of string

  • f : float value

By default, it's a boolean value.

Take a look of available formats with Getopt::Long::Descriptive.

You need to understand that everything is explicit here. If you use Moose and you attribute has isa = 'Array[Int]'>, that will not implied the format 'i@'.

format json : special format support

The parameter will be treat like a json string.

  option 'hash' => (is => 'ro', json => 1);

  myTool --hash='{"a":1,"b":2}' # hash = { a => 1, b => 2 }

negativable

It add the negative version for the option.

  option 'verbose' => (is => 'ro', negativable => 1);

  myTool --verbose    # verbose = 1
  myTool --no-verbose # verbose = 0

repeatable

It append to the "format" the array attribute @.

I advice to add a default value to your attribute to always have an array. Otherwise the default value will be an undefined value.

  option foo => (is => 'rw', format => 's@', default => sub { [] });

  myTool --foo="abc" --foo="def" # foo = ["abc", "def"]

autosplit

For repeatable option, you can add the autosplit feature with your specific parameters.

  option test => (is => 'ro', format => 'i@', default => sub {[]}, autosplit => ',');
  
  myTool --test=1 --test=2 # test = (1, 2)
  myTool --test=1,2,3      # test = (1, 2, 3)

It will also handle quoted params with the autosplit

  option testStr => (is => 'ro', format => 's@', default => sub {[]}, autosplit => ',');

  myTool --testStr='a,b,"c,d",e,f' # testStr ("a", "b", "c,d", "e", "f")

short

Long option can also have short version or aliased.

  option 'verbose' => (is => 'ro', short => 'v');

  myTool --verbose # verbose = 1
  myTool -v        # verbose = 1

  option 'account_id' => (is => 'ro', format => 'i', short => 'a|id');

  myTool --account_id=1
  myTool -a=1
  myTool --id=1

You can also use a shorter option without attribute :

  option 'account_id' => (is => 'ro', format => 'i');

  myTool --acc=1
  myTool --account=1

order

Specified the order of the attribute. If you want to push some attribute at the end of the list. By default all option has an order set to 0, and the option is sorted by their name.

  option 'at_the_end' => (is => 'ro', order => 999);

ADDITIONAL MANUALS

EXTERNAL EXAMPLES

THANKS

Matt S. Trout (mst) <mst@shadowcat.co.uk> : For his patience and advice.
Tomas Doran (t0m) <bobtfish@bobtfish.net> : To help me release the new version, and using it :)
Torsten Raudssus (Getty) : to use it a lot in DuckDuckGo (go to see MooX module also)
Jens Rehsack (REHSACK) : Use with PkgSrc, and many really good idea (MooX::Cmd, MooX::ConfigFromFile, and more to come I'm sure)

BUGS

Please report any bugs or feature requests on the bugtracker website https://github.com/celogeek/MooX-Options/issues

When submitting a bug or request, please include a test-file or a patch to an existing test-file that illustrates the bug or desired feature.

AUTHOR

celogeek <me@celogeek.com>

COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by celogeek <me@celogeek.com>.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.