NAME

strict - Perl pragma to restrict unsafe constructs

SYNOPSIS

    use strict;

    use strict "vars";
    use strict "refs";
    use strict "subs";
    use strict "untie";

    use strict;
    no strict "vars";

DESCRIPTION

If no import list is supplied, all possible restrictions are assumed. (This is the safest mode to operate in, but is sometimes too strict for casual programming.) Currently, there are four possible things to be strict about: "subs", "vars", "refs", and "untie".

strict refs

This generates a runtime error if you use symbolic references (see perlref).

    use strict 'refs';
    $ref = \$foo;
    print $$ref;        # ok
    $ref = "foo";
    print $$ref;        # runtime error; normally ok

strict vars

This generates a compile-time error if you access a variable that wasn't localized via my() or wasn't fully qualified. Because this is to avoid variable suicide problems and subtle dynamic scoping issues, a merely local() variable isn't good enough. See "my" in perlfunc and "local" in perlfunc.

    use strict 'vars';
    $X::foo = 1;         # ok, fully qualified
    my $foo = 10;        # ok, my() var
    local $foo = 9;      # blows up

The local() generated a compile-time error because you just touched a global name without fully qualifying it.

strict subs

This disables the poetry optimization, generating a compile-time error if you try to use a bareword identifier that's not a subroutine, unless it appears in curly braces or on the left hand side of the "=>" symbol.

    use strict 'subs';
    $SIG{PIPE} = Plumber;       # blows up
    $SIG{PIPE} = "Plumber";     # just fine: bareword in curlies always ok
    $SIG{PIPE} = \&Plumber;     # preferred form

strict untie

This generates a runtime error if any references to the object returned by tie (or tied) still exist when untie is called. Note that to get this strict behaviour, the use strict 'untie' statement must be in the same scope as the untie. See "tie" in perlfunc, "untie" in perlfunc, "tied" in perlfunc and perltie.

    use strict 'untie';
    $a = tie %a, 'SOME_PKG';
    $b = tie %b, 'SOME_PKG';
    $b = 0;
    tie %c, PKG;
    $c = tied %c;
    untie %a ;          # blows up, $a is a valid object reference.
    untie %b;           # ok, $b is not a reference to the object.
    untie %c ;          # blows up, $c is a valid object reference.

See "Pragmatic Modules" in perlmod.