Dave Rolsky > File-Slurp-9999.13 > File::Slurp

Download:
File-Slurp-9999.13.tar.gz

Dependencies

Annotate this POD (3)

Related Modules

File::Find
XML::Simple
Data::Dumper
HTML::Template
CGI::Application
Parse::RecDescent
Tie::File
Class::DBI
List::Util
WWW::Mechanize
more...
By perlmonks.org

CPAN RT

New  12
Open  12
View/Report Bugs
Module Version: 9999.13   Source   Latest Release: File-Slurp-9999.19

NAME ^

File::Slurp - Efficient Reading/Writing of Complete Files

SYNOPSIS ^

  use File::Slurp;

  my $text = read_file( 'filename' ) ;
  my @lines = read_file( 'filename' ) ;

  write_file( 'filename', @lines ) ;

  use File::Slurp qw( slurp ) ;

  my $text = slurp( 'filename' ) ;

DESCRIPTION ^

This module provides subs that allow you to read or write entire files with one simple call. They are designed to be simple to use, have flexible ways to pass in or get the file contents and to be very efficient. There is also a sub to read in all the files in a directory other than . and ..

These slurp/spew subs work for files, pipes and sockets, and stdio, pseudo-files, and DATA.

read_file

This sub reads in an entire file and returns its contents to the caller. In list context it will return a list of lines (using the current value of $/ as the separator including support for paragraph mode when it is set to ''). In scalar context it returns the entire file as a single scalar.

  my $text = read_file( 'filename' ) ;
  my @lines = read_file( 'filename' ) ;

The first argument to read_file is the filename and the rest of the arguments are key/value pairs which are optional and which modify the behavior of the call. Other than binmode the options all control how the slurped file is returned to the caller.

If the first argument is a file handle reference or I/O object (if ref is true), then that handle is slurped in. This mode is supported so you slurp handles such as DATA, STDIN. See the test handle.t for an example that does open( '-|' ) and child process spews data to the parant which slurps it in. All of the options that control how the data is returned to the caller still work in this case.

NOTE: as of version 9999.06, read_file works correctly on the DATA handle. It used to need a sysseek workaround but that is now handled when needed by the module itself.

You can optionally request that slurp() is exported to your code. This is an alias for read_file and is meant to be forward compatible with Perl 6 (which will have slurp() built-in).

The options are:

binmode

If you set the binmode option, then the file will be slurped in binary mode.

        my $bin_data = read_file( $bin_file, binmode => ':raw' ) ;

NOTE: this actually sets the O_BINARY mode flag for sysopen. It probably should call binmode and pass its argument to support other file modes.

array_ref

If this boolean option is set, the return value (only in scalar context) will be an array reference which contains the lines of the slurped file. The following two calls are equivalent:

        my $lines_ref = read_file( $bin_file, array_ref => 1 ) ;
        my $lines_ref = [ read_file( $bin_file ) ] ;

scalar_ref

If this boolean option is set, the return value (only in scalar context) will be an scalar reference to a string which is the contents of the slurped file. This will usually be faster than returning the plain scalar.

        my $text_ref = read_file( $bin_file, scalar_ref => 1 ) ;

buf_ref

You can use this option to pass in a scalar reference and the slurped file contents will be stored in the scalar. This can be used in conjunction with any of the other options.

        my $text_ref = read_file( $bin_file, buf_ref => \$buffer,
                                             array_ref => 1 ) ;
        my @lines = read_file( $bin_file, buf_ref => \$buffer ) ;

blk_size

You can use this option to set the block size used when slurping from an already open handle (like \*STDIN). It defaults to 1MB.

        my $text_ref = read_file( $bin_file, blk_size => 10_000_000,
                                             array_ref => 1 ) ;

err_mode

You can use this option to control how read_file behaves when an error occurs. This option defaults to 'croak'. You can set it to 'carp' or to 'quiet to have no error handling. This code wants to carp and then read abother file if it fails.

        my $text_ref = read_file( $file, err_mode => 'carp' ) ;
        unless ( $text_ref ) {

                # read a different file but croak if not found
                $text_ref = read_file( $another_file ) ;
        }
        
        # process ${$text_ref}

write_file

This sub writes out an entire file in one call.

  write_file( 'filename', @data ) ;

The first argument to write_file is the filename. The next argument is an optional hash reference and it contains key/values that can modify the behavior of write_file. The rest of the argument list is the data to be written to the file.

  write_file( 'filename', {append => 1 }, @data ) ;
  write_file( 'filename', {binmode => ':raw' }, $buffer ) ;

As a shortcut if the first data argument is a scalar or array reference, it is used as the only data to be written to the file. Any following arguments in @_ are ignored. This is a faster way to pass in the output to be written to the file and is equivilent to the buf_ref option. These following pairs are equivilent but the pass by reference call will be faster in most cases (especially with larger files).

  write_file( 'filename', \$buffer ) ;
  write_file( 'filename', $buffer ) ;

  write_file( 'filename', \@lines ) ;
  write_file( 'filename', @lines ) ;

If the first argument is a file handle reference or I/O object (if ref is true), then that handle is slurped in. This mode is supported so you spew to handles such as \*STDOUT. See the test handle.t for an example that does open( '-|' ) and child process spews data to the parant which slurps it in. All of the options that control how the data is passes into write_file still work in this case.

write_file returns 1 upon successfully writing the file or undef if it encountered an error.

The options are:

binmode

If you set the binmode option, then the file will be written in binary mode.

        write_file( $bin_file, {binmode => ':raw'}, @data ) ;

NOTE: this actually sets the O_BINARY mode flag for sysopen. It probably should call binmode and pass its argument to support other file modes.

buf_ref

You can use this option to pass in a scalar reference which has the data to be written. If this is set then any data arguments (including the scalar reference shortcut) in @_ will be ignored. These are equivilent:

        write_file( $bin_file, { buf_ref => \$buffer } ) ;
        write_file( $bin_file, \$buffer ) ;
        write_file( $bin_file, $buffer ) ;

atomic

If you set this boolean option, the file will be written to in an atomic fashion. A temporary file name is created by appending the pid ($$) to the file name argument and that file is spewed to. After the file is closed it is renamed to the original file name (and rename is an atomic operation on most OS's). If the program using this were to crash in the middle of this, then the file with the pid suffix could be left behind.

append

If you set this boolean option, the data will be written at the end of the current file.

        write_file( $file, {append => 1}, @data ) ;

write_file croaks if it cannot open the file. It returns true if it succeeded in writing out the file and undef if there was an error. (Yes, I know if it croaks it can't return anything but that is for when I add the options to select the error handling mode).

no_clobber

If you set this boolean option, an existing file will not be overwritten.

        write_file( $file, {no_clobber => 1}, @data ) ;

err_mode

You can use this option to control how write_file behaves when an error occurs. This option defaults to 'croak'. You can set it to 'carp' or to 'quiet' to have no error handling other than the return value. If the first call to write_file fails it will carp and then write to another file. If the second call to write_file fails, it will croak.

        unless ( write_file( $file, { err_mode => 'carp', \$data ) ;

                # write a different file but croak if not found
                write_file( $other_file, \$data ) ;
        }

overwrite_file

This sub is just a typeglob alias to write_file since write_file always overwrites an existing file. This sub is supported for backwards compatibility with the original version of this module. See write_file for its API and behavior.

append_file

This sub will write its data to the end of the file. It is a wrapper around write_file and it has the same API so see that for the full documentation. These calls are equivilent:

        append_file( $file, @data ) ;
        write_file( $file, {append => 1}, @data ) ;

read_dir

This sub reads all the file names from directory and returns them to the caller but . and .. are removed by default.

        my @files = read_dir( '/path/to/dir' ) ;

It croaks if it cannot open the directory.

In a list context read_dir returns a list of the entries in the directory. In a scalar context it returns an array reference which has the entries.

keep_dot_dot

If this boolean option is set, . and .. are not removed from the list of files.

        my @all_files = read_dir( '/path/to/dir', keep_dot_dot => 1 ) ;

EXPORT

  read_file write_file overwrite_file append_file read_dir

SEE ALSO

An article on file slurping in extras/slurp_article.pod. There is also a benchmarking script in extras/slurp_bench.pl.

BUGS

If run under Perl 5.004, slurping from the DATA handle will fail as that requires B.pm which didn't get into core until 5.005.

AUTHOR ^

Uri Guttman, <uri@stemsystems.com>

syntax highlighting: