Karen Etheridge > Moose-2.1210 > Moose::Cookbook::Extending::Mooseish_MooseSugar

Download:
Moose-2.1210.tar.gz

Dependencies

Annotate this POD

Website

CPAN RT

New  13
Open  42
Stalled  7
View/Report Bugs
Module Version: 2.1210   Source   Latest Release: Moose-2.1304-TRIAL

NAME ^

Moose::Cookbook::Extending::Mooseish_MooseSugar - Acting like Moose.pm and providing sugar Moose-style

VERSION ^

version 2.1210

SYNOPSIS ^

  package MyApp::Mooseish;

  use Moose::Exporter;

  Moose::Exporter->setup_import_methods(
      with_meta       => ['has_table'],
      class_metaroles => {
          class => ['MyApp::Meta::Class::Trait::HasTable'],
      },
  );

  sub has_table {
      my $meta = shift;
      $meta->table(shift);
  }

  package MyApp::Meta::Class::Trait::HasTable;
  use Moose::Role;

  has table => (
      is  => 'rw',
      isa => 'Str',
  );

DESCRIPTION ^

This recipe expands on the use of Moose::Exporter we saw in Moose::Cookbook::Extending::ExtensionOverview and the class metaclass trait we saw in Moose::Cookbook::Meta::Table_MetaclassTrait. In this example we provide our own metaclass trait, and we also export a has_table sugar function.

The with_meta parameter specifies a list of functions that should be wrapped before exporting. The wrapper simply ensures that the importing package's appropriate metaclass object is the first argument to the function, so we can do my $meta = shift;.

See the Moose::Exporter docs for more details on its API.

USING MyApp::Mooseish ^

The purpose of all this code is to provide a Moose-like interface. Here's what it would look like in actual use:

  package MyApp::User;

  use namespace::autoclean;

  use Moose;
  use MyApp::Mooseish;

  has_table 'User';

  has 'username' => ( is => 'ro' );
  has 'password' => ( is => 'ro' );

  sub login { ... }

CONCLUSION ^

Providing sugar functions can make your extension look much more Moose-ish. See Fey::ORM for a more extensive example.

AUTHORS ^

COPYRIGHT AND LICENSE ^

This software is copyright (c) 2006 by Infinity Interactive, Inc..

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

syntax highlighting: