Franck Cuny > Dancer-1.1902 > Dancer::Test

Download:
Dancer-1.1902.tar.gz

Dependencies

Annotate this POD

Website

View/Report Bugs
Source   Latest Release: Dancer-1.3130

NAME ^

Dancer::Test - Test helpers to test a Dancer application

SYNOPSYS ^

    use strict;
    use warnings;
    use Test::More tests => 2;

    use MyWebApp;
    use Dancer::Test appdir => '..';

    response_status_is [GET => '/'], 200, "GET / is found";
    response_content_like [GET => '/'], qr/hello, world/, "content looks good for /";

DESCRIPTION ^

This module provides test heplers for testing Dancer apps.

CONFIGURATON ^

When importing Dancer::Test, the appdir is set by defaut to '..', assuming that your test scrtipt is directly in your t/ directory. If you put your test scrtipt deeper in the 't/' hierarchy (like in 't/routes/01_some_test.t') you'll have to tell Dancer::Test that the appdir is one step upper.

To do so, you can tell where the appdir is thanks to an import option:

    use MyWebApp;
    use Dancer::Test appdir => '../..';

Be careful, the order in the example above is very important. Make sure to use Dancer::Test after importing the application package otherwise your appdir will be automatically set to lib and your test script won't be able to find views, conffiles and other application content.

METHODS ^

route_exists([$method, $path], $test_name)

Asserts that the given request matches a route handler in Dancer's registry.

    route_exists [GET => '/'], "GET / is handled";

route_doesnt_exist([$method, $path], $test_name)

Asserts that the given request does not match any route handler in Dancer's registry.

    route_doesnt_exist [GET => '/bogus_path'], "GET /bogus_path is not handled";

response_exists([$method, $path], $test_name)

Asserts that a response is found for the given request (note that even though a route for that path might not exist, a response can be found during request processing, because of filters).

    response_exists [GET => '/path_that_gets_redirected_to_home'],
        "response found for unknown path";

response_doesnt_exist([$method, $path], $test_name)

Asserts that no response is found when processing the given request.

    response_doesnt_exist [GET => '/unknown_path'],
        "response not found for unknown path";

response_status_is([$method, $path], $status, $test_name)

Asserts that Dancer's response for the given request has a status equal to the one given.

    response_status_is [GET => '/'], 200, "response for GET / is 200";

response_status_isnt([$method, $path], $status, $test_name)

Asserts that the status of Dancer's response is not equal to the one given.

    response_status_isnt [GET => '/'], 404, "response for GET / is not a 404";

response_content_is([$method, $path], $expected, $test_name)

Asserts that the response content is equal to the $expected string.

    response_content_is [GET => '/'], "Hello, World", 
        "got expected response content for GET /";

response_content_isnt([$method, $path], $not_expected, $test_name)

Asserts that the response content is not equal to the $not_expected string.

    response_content_is [GET => '/'], "Hello, World", 
        "got expected response content for GET /";

response_content_is_deeply([$method, $path], $expected_struct, $test_name)

Similar to response_content_is(), except that if response content and $expected_struct are references, it does a deep comparison walking each data structure to see if they are equivalent.

If the two structures are different, it will display the place where they start differing.

    response_content_is_deeply [GET => '/complex_struct'], 
        { foo => 42, bar => 24}, 
        "got expected response structure for GET /complex_struct";

response_content_like([$method, $path], $regexp, $test_name)

Asserts that the response content for the given request matches the regexp given.

    response_content_like [GET => '/'], qr/Hello, World/, 
        "response content looks good for GET /";

response_content_unlike([$method, $path], $regexp, $test_name)

Asserts that the response content for the given request does not match the regexp given.

    response_content_unlike [GET => '/'], qr/Page not found/, 
        "response content looks good for GET /";

response_headers_are_deeply([$method, $path], $expected, $test_name)

Asserts that the response headers data structure equals the one given.

    response_headers_are_deeply [GET => '/'], [ 'X-Powered-By' => 'Dancer 1.150' ];

get_response([$method, $path])

Returns a Dancer::Response object for the given request. The status and content can both be accessed with this object. A good reason to use this function is for testing POST requests. Since POST requests may not be idempotent, it is necessary to capture the content and status in one shot. Calling the response_status_is and response_content_is functions in succession would make two requests, each of which could alter the state of the application and cause Schrodinger's cat to die.

    my $response = get_response [POST => '/widgets'];
    is $response->{status}, 202, "response for POST /widgets is 202";
    is $response->{content}, "Widget #1 has been scheduled for creation",
        "response content looks good for first POST /widgets";

    $response = get_response [POST => '/widgets'];
    is $response->{status}, 202, "response for POST /widgets is 202";
    is $response->{content}, "Widget #2 has been scheduled for creation",
        "response content looks good for second POST /widgets";

LICENSE ^

This module is free software and is distributed under the same terms as Perl itself.

AUTHOR ^

This module has been written by Alexis Sukrieh <sukria@sukria.net>

SEE ALSO ^

Test::More

syntax highlighting: