AnyEvent::Redis::RipeRedis - Flexible non-blocking Redis client with reconnect feature
use AnyEvent;
use AnyEvent::Redis::RipeRedis qw( :err_codes );
my $cv = AnyEvent->condvar();
my $redis = AnyEvent::Redis::RipeRedis->new(
host => 'localhost',
port => '6379',
password => 'your_password',
encoding => 'utf8',
on_connect => sub {
print "Connected to Redis server\n";
},
on_disconnect => sub {
print "Disconnected from Redis server\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
warn "$err_msg. Error code: $err_code\n";
},
);
# Set value
$redis->set( 'foo', 'Some string', {
on_done => sub {
my $data = shift;
print "$data\n";
$cv->send();
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
}
} );
$cv->recv();
$redis->disconnect();
AnyEvent::Redis::RipeRedis is a non-blocking flexible Redis client with reconnect feature. It supports subscriptions, transactions, has simple API and it faster than AnyEvent::Redis.
Requires Redis 1.2 or higher, and any supported event loop.
my $redis = AnyEvent::Redis::RipeRedis->new(
host => 'localhost',
port => '6379',
password => 'your_password',
database => 7,
lazy => 1,
connection_timeout => 5,
reconnect => 1,
encoding => 'utf8',
on_connect => sub {
print "Connected to Redis server\n";
},
on_disconnect => sub {
print "Disconnected from Redis server\n";
},
on_connect_error => sub {
my $err_msg = shift;
warn "$err_msg\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
warn "$err_msg. Error code: $err_code\n";
},
);
Server hostname (default: 127.0.0.1)
Server port (default: 6379)
Authentication password. If it specified, then AUTH command will be send immediately to the server after successfully connection and after every successfully reconnection.
Database index. If it set, then client will be switched to specified database immediately after successfully connection and after every successfully reconnection.
Default database index is 0.
Connection timeout. If after this timeout client could not connect to the server, callback on_error is called. By default used kernel's connection timeout.
If this parameter is set, then connection will be established, when you will send a first command to the server. By default connection establishes after calling method new.
If this parameter is TRUE and connection to the Redis server was lost, then client will try to reconnect to server while executing next command. Client try to reconnect only once and if fails, calls on_error callback. If you need several attempts of reconnection, just retry command from on_error callback as many times, as you need. This feature made client more responsive.
By default is TRUE.
Used to encode an decode strings during input/output operations. Not set by default.
Callback on_connect is called, when connection is successfully established. Not set by default.
Callback on_disconnect is called, when connection is closed by any reason. Not set by default.
Callback on_connect_error is called, when the connection could not be established. If this collback isn't specified, then on_error callback is called.
Callback on_error is called, when any error occurred. If callback is no set, client just print error message to STDERR.
# Set value
$redis->set( 'foo', 'Some string' );
# Increment
$redis->incr( 'bar', {
on_done => sub {
my $data = shift;
print "$data\n";
},
} );
# Get list of values
$redis->lrange( 'list', 0, -1, {
on_done => sub {
my $data = shift;
foreach my $val ( @{ $data } ) {
print "$val\n";
}
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
},
} );
Full list of Redis commands can be found here: http://redis.io/commands
Callback on_done is called, when response successfully received.
Callback on_error is called, when any error occurred.
Subscribe to channels by name.
$redis->subscribe( qw( ch_foo ch_bar ), {
on_done => sub {
my $ch_name = shift;
my $subs_num = shift;
print "Subscribed: $ch_name. Active: $subs_num\n";
},
on_message => sub {
my $ch_name = shift;
my $msg = shift;
print "$ch_name: $msg\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
},
} );
Callback on_done is called, when subscription is done.
Callback on_message is called, when published message is successfully received.
Callback on_error is called, when any error occurred.
Subscribe to group of channels by pattern.
$redis->psubscribe( qw( info_* err_* ), {
on_done => sub {
my $ch_pattern = shift;
my $subs_num = shift;
print "Subscribed: $ch_pattern. Active: $subs_num\n";
},
on_message => sub {
my $ch_name = shift;
my $msg = shift;
my $ch_pattern = shift;
print "$ch_name ($ch_pattern): $msg\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
},
} );
Callback on_done is called, when subscription is done.
Callback on_message is called, when published message is successfully received.
Callback on_error is called, when any error occurred.
Unsubscribe from channels by name.
$redis->unsubscribe( qw( ch_foo ch_bar ), {
on_done => sub {
my $ch_name = shift;
my $subs_num = shift;
print "Unsubscribed: $ch_name. Active: $subs_num\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
},
} );
Callback on_done is called, when unsubscription is done.
Callback on_error is called, when any error occurred.
Unsubscribe from group of channels by pattern.
$redis->punsubscribe( qw( info_* err_* ), {
on_done => sub {
my $ch_pattern = shift;
my $subs_num = shift;
print "Unsubscribed: $ch_pattern. Active: $subs_num\n";
},
on_error => sub {
my $err_msg = shift;
my $err_code = shift;
$cv->croak( "$err_msg. Error code: $err_code" );
},
} );
Callback on_done is called, when unsubscription is done.
Callback on_error is called, when any error occurred.
Redis 2.2 and higher support connection via UNIX domain socket. To connect via a UNIX-socket in the parameter host you have to specify unix/, and in the parameter port you have to specify the path to the socket.
my $redis = AnyEvent::Redis::RipeRedis->new(
host => 'unix/',
port => '/tmp/redis.sock',
);
Redis 2.6 and higher support execution of the Lua scripts on the server side. To execute a Lua script you can use one of the commands EVAL or EVALSHA, or you can use special method eval_cached().
When you call eval_cached() method, client first generate SHA1 hash for the Lua script and cache it in memory. Then client optimistically send EVALSHA command under the hood. If NO_SCRIPT error will be returned, client send EVAL command.
If you call eval_cached() method with the same Lua script, client don't generate SHA1 hash for this script repeatedly, it gets hash from cache.
$redis->eval_cached( 'return { KEYS[1], KEYS[2], ARGV[1], ARGV[2] }',
2, 'key1', 'key2', 'first', 'second', {
on_done => sub {
my $data = shift;
foreach my $val ( @{ $data } ) {
print "$val\n";
}
}
} );
Error codes can be used for programmatic handling of errors.
1 - E_CANT_CONN 2 - E_LOADING_DATASET 3 - E_IO 4 - E_CONN_CLOSED_BY_REMOTE_HOST 5 - E_CONN_CLOSED_BY_CLIENT 6 - E_NO_CONN 7 - E_INVALID_PASS 8 - E_OPRN_NOT_PERMITTED 9 - E_OPRN_ERROR 10 - E_UNEXPECTED_DATA 11 - E_NO_SCRIPT
Can't connect to server.
Redis is loading the dataset in memory.
Input/Output operation error. Connection closed.
Connection closed by remote host.
Connection closed unexpectedly by client.
Error occur, if at time of disconnection in client queue were uncompleted commands.
No connection to the server.
Error occur, if at time of command execution connection has been closed by any reason and parameter reconnect was set to FALSE.
Invalid password.
Operation not permitted. Authentication required.
Operation error. Usually returned by the Redis server.
Client received unexpected data from server.
No matching script. Use EVAL command.
To use these constants you have to import them.
use AnyEvent::Redis::RipeRedis qw( :err_codes );
When the connection to the server is no longer needed you can close it in three ways: call method disconnect(), send QUIT command or you can just "forget" any references to an AnyEvent::Redis::RipeRedis object, but in this case client object destroying silently without calling any callbacks including on_disconnect callback to avoid unexpected behavior.
Method for synchronous disconnection.
$redis->disconnect();
AnyEvent, AnyEvent::Redis, Redis, Redis::hiredis, RedisDB
Eugene Ponizovsky, <ponizovsky@gmail.com>
Copyright (c) 2012, Eugene Ponizovsky, <ponizovsky@gmail.com>. All rights reserved.
This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
