Mike McCauley > Digest-MD4-1.9 > Digest::MD4

Download:
DigestMD4/Digest-MD4-1.9.tar.gz

Dependencies

Annotate this POD

Related Modules

Digest::MD5
Digest::SHA1
Digest::MD2
Compress::Zlib
IO::Zlib
more...
By perlmonks.org

CPAN RT

Open  0
View/Report Bugs
Module Version: 1.9   Source  

NAME ^

Digest::MD4 - Perl interface to the MD4 Algorithm

SYNOPSIS ^

 # Functional style
 use Digest::MD4 qw(md4 md4_hex md4_base64);

 $digest = md4($data);
 $digest = md4_hex($data);
 $digest = md4_base64($data);

 # OO style
 use Digest::MD4;

 $ctx = Digest::MD4->new;

 $ctx->add($data);
 $ctx->addfile(*FILE);

 $digest = $ctx->digest;
 $digest = $ctx->hexdigest;
 $digest = $ctx->b64digest;

DESCRIPTION ^

The Digest::MD4 module allows you to use the RSA Data Security Inc. MD4 Message Digest algorithm from within Perl programs. The algorithm takes as input a message of arbitrary length and produces as output a 128-bit "fingerprint" or "message digest" of the input.

The Digest::MD4 module provide a procedural interface for simple use, as well as an object oriented interface that can handle messages of arbitrary length and which can read files directly.

FUNCTIONS ^

The following functions are provided by the Digest::MD4 module. None of these functions are exported by default.

md4($data,...)

This function will concatenate all arguments, calculate the MD4 digest of this "message", and return it in binary form. The returned string will be 16 bytes long.

The result of md4("a", "b", "c") will be exactly the same as the result of md4("abc").

md4_hex($data,...)

Same as md4(), but will return the digest in hexadecimal form. The length of the returned string will be 32 and it will only contain characters from this set: '0'..'9' and 'a'..'f'.

md4_base64($data,...)

Same as md4(), but will return the digest as a base64 encoded string. The length of the returned string will be 22 and it will only contain characters from this set: 'A'..'Z', 'a'..'z', '0'..'9', '+' and '/'.

Note that the base64 encoded string returned is not padded to be a multiple of 4 bytes long. If you want interoperability with other base64 encoded md4 digests you might want to append the redundant string "==" to the result.

METHODS ^

The object oriented interface to Digest::MD4 is described in this section. After a Digest::MD4 object has been created, you will add data to it and finally ask for the digest in a suitable format. A single object can be used to calculate multiple digests.

The following methods are provided:

$md4 = Digest::MD4->new

The constructor returns a new Digest::MD4 object which encapsulate the state of the MD4 message-digest algorithm.

If called as an instance method (i.e. $md4->new) it will just reset the state the object to the state of a newly created object. No new object is created in this case.

$md4->reset

This is just an alias for $md4->new.

$md4->clone

This a copy of the $md4 object. It is useful when you do not want to destroy the digests state, but need an intermediate value of the digest, e.g. when calculating digests iteratively on a continuous data stream. Example:

    my $md4 = Digest::MD4->new;
    while (<>) {
        $md4->add($_);
        print "Line $.: ", $md4->clone->hexdigest, "\n";
    }
$md4->add($data,...)

The $data provided as argument are appended to the message we calculate the digest for. The return value is the $md4 object itself.

All these lines will have the same effect on the state of the $md4 object:

    $md4->add("a"); $md4->add("b"); $md4->add("c");
    $md4->add("a")->add("b")->add("c");
    $md4->add("a", "b", "c");
    $md4->add("abc");
$md4->addfile($io_handle)

The $io_handle will be read until EOF and its content appended to the message we calculate the digest for. The return value is the $md4 object itself.

The addfile() method will croak() if it fails reading data for some reason. If it croaks it is unpredictable what the state of the $md4 object will be in. The addfile() method might have been able to read the file partially before it failed. It is probably wise to discard or reset the $md4 object if this occurs.

In most cases you want to make sure that the $io_handle is in binmode before you pass it as argument to the addfile() method.

$md4->digest

Return the binary digest for the message. The returned string will be 16 bytes long.

Note that the digest operation is effectively a destructive, read-once operation. Once it has been performed, the Digest::MD4 object is automatically reset and can be used to calculate another digest value. Call $md4->clone->digest if you want to calculate the digest without reseting the digest state.

$md4->hexdigest

Same as $md4->digest, but will return the digest in hexadecimal form. The length of the returned string will be 32 and it will only contain characters from this set: '0'..'9' and 'a'..'f'.

$md4->b64digest

Same as $md4->digest, but will return the digest as a base64 encoded string. The length of the returned string will be 22 and it will only contain characters from this set: 'A'..'Z', 'a'..'z', '0'..'9', '+' and '/'.

The base64 encoded string returned is not padded to be a multiple of 4 bytes long. If you want interoperability with other base64 encoded md4 digests you might want to append the string "==" to the result.

EXAMPLES ^

The simplest way to use this library is to import the md4_hex() function (or one of its cousins):

    use Digest::MD4 qw(md4_hex);
    print "Digest is ", md4_hex("foobarbaz"), "\n";

The above example would print out the message:

    Digest is b2b2b528f632f554ae9cb2c02c904eeb

The same checksum can also be calculated in OO style:

    use Digest::MD4;
    
    $md4 = Digest::MD4->new;
    $md4->add('foo', 'bar');
    $md4->add('baz');
    $digest = $md4->hexdigest;
    
    print "Digest is $digest\n";

With OO style you can break the message arbitrary. This means that we are no longer limited to have space for the whole message in memory, i.e. we can handle messages of any size.

This is useful when calculating checksum for files:

    use Digest::MD4;

    my $file = shift || "/etc/passwd";
    open(FILE, $file) or die "Can't open '$file': $!";
    binmode(FILE);

    $md4 = Digest::MD4->new;
    while (<FILE>) {
        $md4->add($_);
    }
    close(FILE);
    print $md4->b64digest, " $file\n";

Or we can use the addfile method for more efficient reading of the file:

    use Digest::MD4;

    my $file = shift || "/etc/passwd";
    open(FILE, $file) or die "Can't open '$file': $!";
    binmode(FILE);

    print Digest::MD4->new->addfile(*FILE)->hexdigest, " $file\n";

Perl 5.8 support Unicode characters in strings. Since the MD4 algorithm is only defined for strings of bytes, it can not be used on strings that contains chars with ordinal number above 255. The MD4 functions and methods will croak if you try to feed them such input data:

    use Digest::MD4 qw(md4_hex);

    my $str = "abc\x{300}";
    print md4_hex($str), "\n";  # croaks
    # Wide character in subroutine entry

What you can do is calculate the MD4 checksum of the UTF-8 representation of such strings. This is achieved by filtering the string through encode_utf8() function:

    use Digest::MD4 qw(md4_hex);
    use Encode qw(encode_utf8);

    my $str = "abc\x{300}";
    print md4_hex(encode_utf8($str)), "\n";
    # fc2ef2836f9bc3f44ed6d7adee2f1533

SEE ALSO ^

Digest, Digest::MD2, Digest::SHA1, Digest::HMAC

md4sum(1)

RFC 1320

COPYRIGHT ^

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

 Copyright 1998-2003 Gisle Aas.
 Copyright 1995-1996 Neil Winton.
 Copyright 1991-1992 RSA Data Security, Inc.

The MD4 algorithm is defined in RFC 1320. This implementation is derived from the reference C code in RFC 1320 which is covered by the following copyright statement:

This copyright does not prohibit distribution of any version of Perl containing this extension under the terms of the GNU or Artistic licenses.

AUTHORS ^

The original MD5 interface was written by Neil Winton (N.Winton@axion.bt.co.uk).

The Digest::MD5 module is written by Gisle Aas <gisle@ActiveState.com>.

The Digest::MD4 module is derived from Digest::MD5 by Mike McCauley (mikem@airspayce.com)

syntax highlighting: