View on
MetaCPAN is shutting down
For details read Perl NOC. After June 25th this page will redirect to
Marcus Ramberg > Catalyst-Runtime-5.8000_07 > lib/Catalyst/Upgrading.pod


Annotate this POD



New  15
Open  13
View/Report Bugs
Source   Latest Release: Catalyst-Runtime-5.90118

Upgrading to Catalyst 5.80 ^

Most applications and plugins should run unaltered on Catalyst 5.80.

However as a lot of refactoring work has taken place, and several changes have been made which could cause incompatibilities. If your application or plugin is using deprecated code, or relying on side-effects, then you could have issues upgrading to this release.

Most issues found with pre-existing components have been easy to solve, and a complete description of behaviour changes which may cause compatibility issues, or warnings which are now emitted is included below to help if you have problems.

If you think you have found an upgrade related issue which is not covered in this document, then please email the Catalyst list to discuss the problem.

Known backwards compatibility breakages. ^

Issues with Class::C3

Catalyst 5.80 uses Algorithm::C3 method dispatch order. This is built into perl 5.10, and comes via Class::C3 for perl 5.8. This replaces NEXT with Class::C3::Adopt::NEXT, forcing all components to resolve methods using C3, rather than the unpredictable dispatch order of NEXT.

To be able to do this, however, entails that the graph of superclasses for each class must be linearizable using the C3 algorithm. Unfortunately, when superclasses are being used as mixins, it is easy to get this wrong.

Most common is the case of:

    package Component1; # Note, this is the common case
    use base qw/Class::Accessor::Fast Class::Data::Inheritable/;

    package Component2; # Accidentally saying it this way round causes fail.
    use base qw/Class::Data::Inheritable Class::Accessor::Fast/;

    package GoesBang;
    use base qw/Component1 Component2/;

And the Catalyst plugin most often causing this, is Catalyst::Plugin::Sesssion::Store::FastMMap - if you are using this plugin and see issues, then please upgrade!

This can, however, be found in your own application - the only solution is to go through each base class of the class the error was reported against, until you identify the ones in conflict, and resolve them.

Components which inherit from Moose::Object before Catalyst::Component

Moose components which say:

    package TestApp::Controller::Example;
    use Moose;
    extends qw/Moose::Object Catalyst::Component/;

to use the constructor provided by Moose, whilst working (if you do some hacks with the BUILDARGS method), will not work with Catalyst 5.80 as Catalyst::Component inherits from Moose::Object, and so @ISA fails to linearise.

The fix for this is to not inherit directly from Moose::Object yourself. Having components which do not inherit their constructor from Catalyst::Component is unsupported, and has never been recommended, therefore you're on your own if you're using this technique. You'll need to detect the version of Catalyst your application is running with and deal with it appropriately.

You will also see this issue if you do the following:

    package TestApp::Controller::Example;
    use Moose;
    use base 'Catalyst::Controller';

as use base appends to @ISA.

The correct way to use Moose in a component in a both forward and backwards compatible way is:

    package TestApp::Controller::Root;
    use Moose;
    BEGIN { extends 'Catalyst::Component' }; # Or ::Controller, or whatever

Note that the extends declaration needs to occur in a begin block for attributes to operate correctly. You also don't get the Moose::Object constructor, and therefore attribute initialization will not work as normally expected. If you want to use Moose attributes, then they need to be made lazy to correctly initialize.

use Moose in MyApp

Similar to the above, this will also fail:

    package MyApp;
    use Moose;
    use Catalyst qw/

If you need to use Moose in your application class (e.g. for method modifiers etc) then the correct technique is:

    package MyApp;
    use Moose;
    extends 'Catalyst';

Anonymous closures installed directly into the symbol table

If you have any code which installs anonymous subroutine references directly into the symbol table, you may encounter breakages. The simplest solution is to use Sub::Name to name the subroutine. Example:

    # Original code, likely to break:
    my $full_method_name = join('::', $package_name, $method_name);
    *$full_method_name = sub { ... };

    # Fixed Code
    use Sub::Name 'subname';
    my $full_method_name = join('::',$package_name, $method_name);
    *$full_method_name = subname $full_method_name, sub { ... };

Additionally, you can take advantage of Catalysts use of Class::MOP and install the closure using the appropriate metaclass. Example:

    use Class::MOP;
    my $metaclass = Moose::Meta::Class->initialize($package_name);
    $metaclass->add_method($method_name => sub { ... });

Hooking into application setup

To execute code during application startup the following snippet in used to work:

    sub setup {
        my ($class, @args) = @_;
        ... # things to do after the actual setup

With Catalyst 5.80 this won't work anymore. Due to the fact that Catalyst is no longer using for method resolution, this no longer works. The functionality was only ever originally operational as NEXT remembers what methods have already been called, and will not call them again.

Using this now causes infinite recursion between MyApp::setup and Catalyst::setup, due to other backwards compatibility issues related to how plugin setup works. Moose method modifiers like before|after|around 'setup => sub { ... }; also will not operate correctly on the setup method.

The right way to do it is this:

    after setup_finalize => sub {
        ... # things to do after the actual setup

The setup_finalize hook was introduced as a way to void this issue.

Components with a new method which returns false

Previously, if you had a component which inherited from Catalyst::COMPONENT, but overrode the new method to return false, then your class' configuration would be blessed into a hash on your behalf, and this would be returned from the COMPONENT method.

This behaviour makes no sense, and so has been removed. Implementing your own new method in components is highly discouraged, instead, you should inherit the new method from Catalyst::Component, and use Mooses BUILD functionality and/or Moose attributes to perform any construction work necessary for your class.


Won't work due to a limitation of Moose. This is currently being fixed inside Moose.

Class::Data::Inheritable side effects

Previously, writing to a class data accessor would copy the accessor method down into your package.

This behaviour has been removed. Whilst the class data is still stored per-class, it is stored on the metaclass of the class defining the accessor.

Therefore anything relying on the side-effect of the accessor being copied down will be broken.

The following test demonstrates the problem:

        package BaseClass;
        use base qw/Class::Data::Inheritable/;

        package Child;
        use base qw/BaseClass/;

    BaseClass->foo('base class');
    Child->foo('sub class');
    use Test::More;
    isnt(BaseClass->can('foo'), Child->can('foo'));

Extending Catalyst::Request or other classes in an ad-hoc manor using mk_accessors

Previously, it was possible to add additional accessors to Catalyst::Request (or other classes) by calling the mk_accessors class method.

This is no longer supported - users should make a sub-class of the class whose behaviour they would like to change, rather than globally polluting the Catalyst objects.

Confused multiple inheritance with Catalyst::Component::COMPONENT

Previously, Catalyst's COMPONENT method would delegate to the method on the right hand side, which could then delegate back again with NEXT. This (as it is insane AND makes no sense with C3 method dispatch order), and is therefore no longer supported.

If a COMPONENT method is detected in the inheritance hierarchy to the right hand side of Catalyst::Component::COMPONENT, then the following warning message will be emitted:

    There is a COMPONENT method resolving after Catalyst::Component
    in ${next_package}.

The correct fix is to re-arrange your class' inheritance hierarchy so that the COMPONENT method you would like to inherit is the first (left-hand most) COMPONENT method in your @ISA.


Methods in Catalyst::Dispatcher

The following methods in Catalyst::Dispatcher are both an implementation detail, which may change in the 5.8X release series, and therefore their use is highly deprecated.


The first time one of these methods is called, a warning will be emitted:

    Class $class is calling the deprecated method Catalyst::Dispatcher::$public_method_name,
    this will be removed in Catalyst 5.9X

You should NEVER be calling any of these methods from application code.

Plugins authors and maintainers whose plugins currently call these methods should change to using the public API, or, if you do not feel the public API adequately supports your use-case, please email the development list to discuss what API features you need so that you can be appropriately supported.

Class naming to packages defined does not correspond.

In this version of Catalyst, if a component is loaded from disk, but no symbols are defined in that component's name space after it is loaded, this warning will be issued:

    require $class was successful but the package is not defined.

This is to protect against confusing bugs caused by mis-typing package names, and will become a fatal error in a future version.

Please note that 'inner packages' (via Devel::InnerPackage) are still fully supported, this warning is only issued when component file naming does not map to any of the packages defined within that component.

$c->plugin method

Calling the plugin method is deprecated, and calling it at runtime is highly deprecated.

Instead you are recommended to use " Catalyst::Model::Adaptor " or similar to compose the functionality you need outside of the main application name space.

Calling the plugin method will not be supported past Catalyst 5.81.

syntax highlighting: