The Perl Toolchain Summit needs more sponsors. If your company depends on Perl, please support this very important event.
 / 
HTML-Restrict-0.06
River stage one • 3 direct dependents • 9 total dependents
12 ++
/ HTML::Restrict

NAME

HTML::Restrict - Strip unwanted HTML tags and attributes (beta)

VERSION

Version 0.06

SYNOPSIS

This module uses HTML::Parser to strip HTML from text in a restrictive manner. By default all HTML is restricted. You may alter the default behaviour by supplying your own tag rules.

This is a beta release.

    use HTML::Restrict;

    my $hr = HTML::Restrict->new();

    # use default rules to start with (strip away all HTML)
    my $processed = $hr->process('<b>i am bold</b>');

    # $processed now equals: i am bold

    ##########################################################################
    # Now, a less restrictive example:
    ##########################################################################

    use HTML::Restrict;

    my $hr = HTML::Restrict->new();
    $hr->set_rules({
        b   => [],
        img => [qw( src alt / )]
    });

    my $html = q[<body><b>hello</b> <img src="pic.jpg" alt="me" id="test" /></body>];
    my $processed = $hr->process( $html );

    # $processed now equals: <b>hello</b> <img src="pic.jpg" alt="me" />

CONSTRUCTOR AND STARTUP

new()

Creates and returns a new HTML::Restrict object.

    my $hr = HTML::Restrict->new()

HTML::Restrict doesn't require any params to be passed to new. If your goal is to remove all HTML from text, then no further setup is required. Just pass your text to the process() method and you're done:

    my $plain_text = $hr->process( $html );

If you need to set up specific rules, have a look at the params which HTML::Restrict recognizes:

  • rules => \%rules

    Rules should be passed as a HASHREF of allowed tags. Each hash value should represent the allowed attributes for the listed tag. For example, if you want to allow a fair amount of HTML, you can try something like this:

        my %rules = (
        a       => [qw( href target )],
        b       => [],
        caption => [],
        center  => [],
        em      => [],
        i       => [],
        img     => [qw( alt border height width src style / )],
        li      => [],
        ol      => [],
        p       => [qw(style)],
        span    => [qw(style)],
        strong  => [],
        sub     => [],
        sup     => [],
        table   => [qw( style border cellspacing cellpadding align )],
        tbody   => [],
        td      => [],
        tr      => [],
        u       => [],
        ul      => [],
    );

    my $hr = HTML::Restrict->new( rules => \%rules )

    Or, to allow only bolded text:

        my $hr = HTML::Restrict->new( rules => { b => [] } );

    Allow bolded text, images and some (but not all) image attributes:

        my %rules = (
        b   => [ ],
        img => [qw( src alt width height border / )
    );
    my $hr = HTML::Restrict->new( rules => \%rules );

    Since HTML::Parser treats a closing slash as an attribute, you'll need to add "/" to your list of allowed attributes if you'd like your tags to retain closing slashes. For example:

        my $hr = HTML::Restrict->new( rules =>{ hr => [] } );
    $hr->process( "<hr />"); # returns: <hr>

    my $hr = HTML::Restrict->new( rules =>{ hr => [qw( / )] } );
    $hr->process( "<hr />"); # returns: <hr />

    HTML::Restrict strips away any tags and attributes which are not explicitly allowed. It also rebuilds your explicitly allowed tags and places their attributes in the order in which they appear in your rules.

    So, if you define the following rules:

        my %rules = (
        ...
        img => [qw( src alt title width height id / )]
        ...
    );

    then your image tags will all be built like this:

        <img src=".." alt="..." title="..." width="..." height="..." id=".." />

    This gives you greater consistency in your tag layout. If you don't care about element order you don't need to pay any attention to this, but you should be aware that your elements are being reconstructed rather than just stripped down.

  • trim => [0|1]

    By default all leading and trailing spaces will be removed when text is processed. Set this value to 0 in order to disable this behaviour.

SUBROUTINES/METHODS

process( $html )

This is the method which does the real work. It parses your data, removes any tags and attributes which are not specifically allowed and returns the resulting text. Requires and returns a SCALAR.

get_rules

An accessor method, which returns a HASHREF of allowed tags and their allowed attributes. Returns an empty HASHREF by default, since the default behaviour is to disallow all HTML.

set_rules( \%rules )

Sets the rules which will be used to process your data. By default all HTML tags are off limits. Use this method to define the HTML elements and corresponding attributes you'd like to use.

If you only need to set rules once, you might want to pass them to the new() method when constructing the object, but you may also set your rules using set_rules(). If you want to apply different rules to different data without creating a new object each time, set_rules() will handle changing the object's behaviour for you.

Please note that set_rules is a mutator method, so your changes are not cumulative. The last rules passed to the set_rules method are the rules which will be applied to your data when it is processed.

For example:

    # create object which allows only a and img tags
    my $hr = HTML::Restrict->new( rules => { a => [ ...], img => [ ... ] } );

    # return to defaults (no HTML allowed)
    $hr->set_rules({});

trim( 0|1 )

By default all leading and trailing spaces will be removed when text is processed. Set this value to 0 in order to disable this behaviour.

MOTIVATION

There are already several modules on the CPAN which accomplish much of the same thing, but after doing a lot of poking around, I was unable to find a solution with a simple setup which I was happy with.

The most common use case might be stripping HTML from user submitted data completely or allowing just a few tags and attributes to be displayed. This module doesn't do any validation on the actual content of the tags or attributes. If this is a requirement, you can either mess with the parser object, post-process the text yourself or have a look at one of the more feature-rich modules in the SEE ALSO section below.

My aim here is to keep things easy and, hopefully, cover a lot of the less complex use cases with just a few lines of code and some brief documentation. The idea is to be up and running quickly.

SEE ALSO

HTML::TagFilter, HTML::Defang, HTML::Declaw, HTML::StripScripts, HTML::Detoxifier, HTML::Sanitizer, HTML::Scrubber

AUTHOR

Olaf Alders, <olaf at wundercounter.com>

BUGS AND LIMITATIONS

Please report any bugs or feature requests to bug-html-restrict at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=HTML-Restrict. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc HTML::Restrict

You can also look for information at:

ACKNOWLEDGEMENTS

Thanks to Raybec Communications http://www.raybec.com for funding my work on this module and for releasing it to the world.

Thanks also to the following for patches and bug reports:

Mark Jubenville (ioncache)

Duncan Forsyth

LICENSE AND COPYRIGHT

Copyright 2009 Olaf Alders.

This program is free software; you can redistribute it and/or modify it under the terms of either: the GNU General Public License as published by the Free Software Foundation; or the Artistic License.

See http://dev.perl.org/licenses/ for more information.