NAME

Moose - A complete modern object system for Perl 5

SYNOPSIS

  package Point;
  use strict;
  use warnings;
  use Moose;
        
  has 'x' => (is => 'rw', isa => 'Int');
  has 'y' => (is => 'rw', isa => 'Int');
  
  sub clear {
      my $self = shift;
      $self->x(0);
      $self->y(0);    
  }
  
  package Point3D;
  use strict;
  use warnings;  
  use Moose;
  
  extends 'Point';
  
  has 'z' => (is => 'rw', isa => 'Int');
  
  after 'clear' => sub {
      my $self = shift;
      $self->z(0);
  };
  

CAVEAT

Moose is a rapidly maturing module, and is already being used by a number of people. It's test suite is growing larger by the day, and the docs should soon follow.

This said, Moose is not yet finished, and should still be considered to be evolving. Much of the outer API is stable, but the internals are still subject to change (although not without serious thought given to it).

DESCRIPTION

Moose is an extension of the Perl 5 object system.

Another object system!?!?

Yes, I know there has been an explosion recently of new ways to build object's in Perl 5, most of them based on inside-out objects and other such things. Moose is different because it is not a new object system for Perl 5, but instead an extension of the existing object system.

Moose is built on top of Class::MOP, which is a metaclass system for Perl 5. This means that Moose not only makes building normal Perl 5 objects better, but it also provides the power of metaclass programming.

Can I use this in production? Or is this just an experiment?

Moose is based on the prototypes and experiments I did for the Perl 6 meta-model; however Moose is NOT an experiment/prototype, it is for real. I will be deploying Moose into production environments later this year, and I have every intentions of using it as my de facto class builder from now on.

Is Moose just Perl 6 in Perl 5?

No. While Moose is very much inspired by Perl 6, it is not itself Perl 6. Instead, it is an OO system for Perl 5. I built Moose because I was tired or writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So instead of switching to Ruby, I wrote Moose :)

BUILDING CLASSES WITH MOOSE

Moose makes every attempt to provide as much convenience as possible during class construction/definition, but still stay out of your way if you want it to. Here are a few items to note when building classes with Moose.

Unless specified with extends, any class which uses Moose will inherit from Moose::Object.

Moose will also manage all attributes (including inherited ones) that are defined with has. And assuming that you call new, which is inherited from Moose::Object, then this includes properly initializing all instance slots, setting defaults where appropriate, and performing any type constraint checking or coercion.

EXPORTED FUNCTIONS

Moose will export a number of functions into the class's namespace which can then be used to set up the class. These functions all work directly on the current class.

meta

This is a method which provides access to the current class's metaclass.

extends (@superclasses)

This function will set the superclass(es) for the current class.

This approach is recommended instead of use base, because use base actually pushes onto the class's @ISA, whereas extends will replace it. This is important to ensure that classes which do not have superclasses still properly inherit from Moose::Object.

with (@roles)

This will apply a given set of @roles to the local class. Role support is currently under heavy development; see Moose::Role for more details.

has ($name, %options)

This will install an attribute of a given $name into the current class. The list of %options are the same as those provided by Class::MOP::Attribute, in addition to the list below which are provided by Moose (Moose::Meta::Attribute to be more specific):

is => 'rw'|'ro'

The is option accepts either rw (for read/write) or ro (for read only). These will create either a read/write accessor or a read-only accessor respectively, using the same name as the $name of the attribute.

If you need more control over how your accessors are named, you can use the reader, writer and accessor options inherited from Class::MOP::Attribute.

isa => $type_name

The isa option uses Moose's type constraint facilities to set up runtime type checking for this attribute. Moose will perform the checks during class construction, and within any accessors. The $type_name argument must be a string. The string can be either a class name or a type defined using Moose's type definition features.

coerce => (1|0)

This will attempt to use coercion with the supplied type constraint to change the value passed into any accessors or constructors. You must have supplied a type constraint in order for this to work. See Moose::Cookbook::Recipe5 for an example usage.

does => $role_name

This will accept the name of a role which the value stored in this attribute is expected to have consumed.

required => (1|0)

This marks the attribute as being required. This means a value must be supplied during class construction, and the attribute can never be set to undef with an accessor.

weak_ref => (1|0)

This will tell the class to store the value of this attribute as a weakened reference. If an attribute is a weakened reference, it cannot also be coerced.

lazy => (1|0)

This will tell the class to not create this slot until absolutely necessary. If an attribute is marked as lazy it must have a default supplied.

auto_deref => (1|0)

This tells the accessor whether to automatically dereference the value returned. This is only legal if your isa option is either an ArrayRef or HashRef.

trigger => $code

The trigger option is a CODE reference which will be called after the value of the attribute is set. The CODE ref will be passed the instance itself, the updated value and the attribute meta-object (this is for more advanced fiddling and can typically be ignored in most cases). You cannot have a trigger on a read-only attribute.

handles => [ @handles ]

There is experimental support for attribute delegation using the handles option. More docs to come later.

before $name|@names => sub { ... }

after $name|@names => sub { ... }

around $name|@names => sub { ... }

This three items are syntactic sugar for the before, after, and around method modifier features that Class::MOP provides. More information on these can be found in the Class::MOP documentation for now.

super

The keyword super is a no-op when called outside of an override method. In the context of an override method, it will call the next most appropriate superclass method with the same arguments as the original method.

override ($name, &sub)

An override method is a way of explicitly saying "I am overriding this method from my superclass". You can call super within this method, and it will work as expected. The same thing can be accomplished with a normal method call and the SUPER:: pseudo-package; it is really your choice.

inner

The keyword inner, much like super, is a no-op outside of the context of an augment method. You can think of inner as being the inverse of super; the details of how inner and augment work is best described in the Moose::Cookbook.

augment ($name, &sub)

An augment method, is a way of explicitly saying "I am augmenting this method from my superclass". Once again, the details of how inner and augment work is best described in the Moose::Cookbook.

confess

This is the Carp::confess function, and exported here because I use it all the time. This feature may change in the future, so you have been warned.

blessed

This is the Scalar::Uti::blessed function, it is exported here because I use it all the time. It is highly recommended that this is used instead of ref anywhere you need to test for an object's class name.

UNEXPORTING FUNCTIONS

unimport

Moose offers a way of removing the keywords it exports though the unimport method. You simply have to say no Moose at the bottom of your code for this to work. Here is an example:

    package Person;
    use Moose;

    has 'first_name' => (is => 'rw', isa => 'Str');
    has 'last_name'  => (is => 'rw', isa => 'Str');
    
    sub full_name { 
        my $self = shift;
        $self->first_name . ' ' . $self->last_name 
    }
    
    no Moose; # keywords are removed from the Person package    

MISC.

What does Moose stand for??

Moose doesn't stand for one thing in particular, however, if you want, here are a few of my favorites; feel free to contribute more :)

Make Other Object Systems Envious

Makes Object Orientation So Easy

Makes Object Orientation Spiffy- Er (sorry ingy)

Most Other Object Systems Emasculate

Moose Often Ovulate Sorta Early

Moose Offers Often Super Extensions

Meta Object Orientation Syntax Extensions

CAVEATS

• It should be noted that super and inner cannot be used in the same method. However, they can be combined together with the same class hierarchy; see t/014_override_augment_inner_super.t for an example.

  The reason for this is that super is only valid within a method with the override modifier, and inner will never be valid within an override method. In fact, augment will skip over any override methods when searching for its appropriate inner.

  This might seem like a restriction, but I am of the opinion that keeping these two features separate (but interoperable) actually makes them easy to use, since their behavior is then easier to predict. Time will tell if I am right or not.

ACKNOWLEDGEMENTS

I blame Sam Vilain for introducing me to the insanity that is meta-models.

I blame Audrey Tang for then encouraging my meta-model habit in #perl6.

Without Yuval "nothingmuch" Kogman this module would not be possible, and it certainly wouldn't have this name ;P

The basis of the TypeContraints module was Rob Kinyon's idea originally, I just ran with it.

Thanks to mst & chansen and the whole #moose poose for all the ideas/feature-requests/encouragement

Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.

SEE ALSO

Class::MOP documentation

The #moose channel on irc.perl.org

The Moose mailing list - moose@perl.org

http://forum2.org/moose/

http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf

This paper (suggested by lbr on #moose) was what lead to the implementation of the super/overrride and inner/augment features. If you really want to understand this feature, I suggest you read this.

BUGS

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Stevan Little <stevan@iinteractive.com>

Christian Hansen <chansen@cpan.org>

Yuval Kogman <nothingmuch@woobling.org>

COPYRIGHT AND LICENSE

Copyright 2006 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

cpanm Moose

perl -MCPAN -e shell
install Moose